Meerdere Word-documenten batchgewijs converteren en bijvoegen als PDF Bestanden naar een Outlook-e-mail

Outlook-oplossingen 29 september 2025

Het is gemakkelijk om een ​​Word-document als PDF bestand naar een Outlook-e-mail. Maar als u meerdere Word-documenten als PDF bestanden naar een e-mail, kunt u dit artikel lezen. Hier laten we u een methode zien om het in batch te krijgen.

Om een ​​Word-document als PDF Om een ​​Word-bestand naar een Outlook-e-mail te verzenden, kunt u eerst het Word-document openen en naar het menu 'Bestand' gaan. Vervolgens kunt u overschakelen naar het tabblad 'Opslaan en verzenden', waar u de knop 'Verzenden als PDF' vindt, zoals in de onderstaande schermafbeelding.

Verzenden als pdf

Het is dus vrij eenvoudig om een ​​Word-document als PDF naar een e-mail. Maar als u meerdere Word-documenten wilt converteren en bijvoegen als PDF bestanden naar een mail, kunt u beter de volgende manier gebruiken. Het kan je het in bulk laten doen.

Batch Converteer en voeg meerdere Word-documenten toe als PDF Bestanden naar een e-mail

  1. Begin met het verzamelen van de Word-documenten die u wilt bewaren in dezelfde Windows-map.
  2. Start vervolgens het Outlook-programma.
  3. Kopieer vervolgens de volgende code naar een ongebruikt project of module.
Dim objMail As Outlook.MailItem

Sub BatchAttachMultipleWordDocumentsAsPDFToEmail()
    Dim objShell As Object
    Dim objWindowsFolder As Object
    Dim strWindowsFolder As String

    Set objMail = Outlook.Application.CreateItem(olMailItem)

    'Select the specific Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows folder:", 0, "")

    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"

       Call ProcessFolders(strWindowsFolder)

       objMail.Display
    End If
End Sub

Sub ProcessFolders(strPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim strDocumentName As String
    Dim strPDF As String

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strPath)

    For Each objFile In objFolder.Files
        strFileExtension = objFileSystem.GetExtensionName(objFile)
        If LCase(strFileExtension) = "doc" Or LCase(strFileExtension) = "docx" Then
           Set objWordApp = CreateObject("Word.Application")
           Set objWordDocument = objWordApp.Documents.Open(objFile.Path)

           'Convert document to pdf
           strDocumentName = Left(objWordDocument.Name, (Len(objWordDocument.Name) - Len(strFileExtension)) - 1)
           strPDF = strPath & strDocumentName & ".pdf"
           objWordDocument.ExportAsFixedFormat strPDF, wdExportFormatPDF

           objWordDocument.Close False

           'Attach the pdf to email
           objMail.Attachments.Add strPDF

           Kill strPDF
        End If
    Next

    'Process all folders and subfolders
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
              ProcessFolders (objSubfolder.Path)
           End If
       Next
    End If
End Sub

VBA-code - Batch converteren en meerdere Word-documenten bijvoegen als PDF Bestanden naar een e-mail

  1. Verplaats daarna de cursor naar de eerste subroutine.
  2. Druk vervolgens op "F5" om deze macro meteen uit te voeren.
  3. Selecteer in het kleine pop-upvenster de Windows-map waarin de Word-brondocumenten zijn opgeslagen.Selecteer Windows-map
  4. Er wordt meteen een nieuwe e-mail aangemaakt, waarin u de bijgevoegde kunt zien PDF bestanden, zoals de volgende screenhost.Attached PDF Bestanden in nieuwe e-mail

Geplaagd door Outlook-problemen

Heeft u last van diverse Outlook-problemen? Outlook zit bijvoorbeeld vaak vast in de status "reageert niet" of het Outlook PST-bestand wordt ontoegankelijk, enz. In het algemeen kunt u eerst de inbox-reparatietool proberen, scanpst, om PST-problemen op te lossen. Maar soms kunnen de problemen verder gaan dan wat de ingebouwde tool kan doen. Daarom kun je beter een krachtiger extern hulpprogramma in de buurt houden, zoals DataNumen Outlook Repair.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder sql reparatie en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com

Reacties zijn gesloten.