Hoe u de categorieën van een e-mail automatisch kunt toepassen op alle antwoorden en doorsturen in Outlook

Wanneer u een e-mail beantwoordt of doorstuurt, wilt u wellicht dezelfde categorieën toepassen. In dit artikel leren we je dit te realiseren met VBA-code.

Als u gewend bent om dezelfde kleurcategorieën van originele e-mail toe te wijzen aan alle antwoorden en doorgestuurde berichten, waarom laat u Outlook dit dan niet automatisch doen? Ook al biedt Outlook niet zo'n directe functie, je kunt deze toch verkrijgen met behulp van VBA-code. In het volgende zullen we de gedetailleerde stappen en code aan u blootleggen.

Pas automatisch de categorieën van een e-mail toe op alle antwoorden en doorgestuurde berichten

1. Start vanaf het begin de Outlook-applicatie.
2. Druk vervolgens op de toetsen "Alt + F11" om de Outlook VBA-editor uit te voeren.
3. Kopieer vervolgens de volgende VBA-code naar het project "ThisOutlookSession".

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem
Private strCategories As String

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call CopyCategories(Forward)
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub CopyCategories(ByVal objNewMail As Object)
    objNewMail.Categories = strCategories
End Sub

4. Start daarna Outlook opnieuw op om dit project te activeren.
5. Sindsdien kunt u het proberen door de onderstaande stappen te volgen.

• Selecteer eerst een e-mail en klik op de knop "Doorsturen".
• Vervolgens wordt er een doorstuur-e-mail weergegeven, waarin u naar het tabblad “Opties” kunt gaan en op het extensiepictogram in de rechter benedenhoek van de groep “Meer opties” kunt klikken.
• Vervolgens kunt u in het pop-upvenster “Eigenschappen” zien dat deze e-mail is toegewezen aan dezelfde kleurcategorieën als de originele e-mail.

Herstel een beschadigd Outlook-bestand

Gezien het feit dat Outlook kwetsbaar is, moet u veel maatregelen nemen om verlies van Outlook-gegevens te voorkomen. U moet bijvoorbeeld periodiek gegevensback-ups maken. Bovendien is het noodzakelijk dat u op uw hoede bent voor onbekende e-mails, inclusief de ingesloten links of bijlagen. Als laatste, maar daarom niet minder belangrijk, zou je een uitstekend extern reparatiehulpmiddel moeten aanschaffen, zoals DataNumen Outlook Repair. Het kan u helpen om maximale gegevens uit te halen corrupte Outlook bestand.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder SQL Server repareren en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com