3 Methoden om e-mails uit een Windows-map naar uw Outlook te importeren

Misschien heeft u verschillende Outlook-e-mails in uw Windows-map opgeslagen. Als u ze nu terug naar een Outlook-map wilt importeren, hoe kunt u dat dan doen? In dit artikel leer je 3 manieren.

Zoals we allemaal weten, biedt Outlook een ingebouwde optie - "Opslaan als", waarmee u de e-mails in de Windows-map kunt opslaan. Er is echter geen functie om de geëxporteerde e-mails opnieuw toe te voegen aan de Outlook-map. Daarom, als u de Outlook-e-mails terug naar Outlook wilt importeren, hoe kunt u dit dan realiseren? In het volgende leren we u 3 methoden. U kunt er een kiezen volgens uw voorkeur.

Methode 1: slepen en neerzetten om te importeren

1. Om te beginnen moet u de bronmap van Windows openen waarin de Outlook-e-mails zijn opgeslagen die in Outlook moeten worden geïmporteerd.
2. Start vervolgens uw Outlook-applicatie.
3. Open vervolgens de Outlook-map waarnaar u de e-mails wilt importeren.
4. Vervolgens moet u zowel het Windows-mapvenster als het Outlook-venster verkleinen totdat u ze in de tussentijd kunt bekijken.
5. Daarna kunt u in de Windows-map een van de Outlook-e-mails selecteren en vervolgens op "Ctrl + A" drukken om ze allemaal te selecteren.
6. Later kunt u de geselecteerde e-mails slepen en neerzetten in de zichtbare Outlook-map, zoals in de volgende schermafbeelding:
7. Ten slotte zult u zien dat alle Outlook-e-mails zijn geïmporteerd vanuit de Windows-map naar de Outlook-map, zoals in de onderstaande afbeelding:

Methode 2: Gebruik "CreateItemFromTemplate" in VBA

1. Om te beginnen drukt u in het hoofdvenster van Outlook op de toetsencombinatie "Alt + F11".
2. Vervolgens krijgt u toegang tot het Outlook VBA-editorvenster.
3. Kopieer vervolgens de volgende VBA-code naar een lege module.

Sub ImportAllOutlookEmailsfromLocaltoOutlook1()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
  
        If strFileType = "msg" Then
           Set objItem = Outlook.Application.CreateItemFromTemplate(objFile.Path)
 
           objItem.Move objTargetFolder
           'Delete the source file in the Windows folder
           'objFileSystem.DeleteFile (objFile.Path)
        End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

4. Vervolgens kunt u in het huidige modulevenster op de F5-toets drukken om de macro te starten.
5. Daarna moet u naar de bronmap van Windows in het pop-upvenster bladeren.
6. Ten slotte, na het selecteren van de bronmap, worden alle Outlook-items in die map geïmporteerd in de vooraf gedefinieerde Outlook-map.
7. Opmerking: op deze manier zijn de geïmporteerde e-mails allemaal verse nieuwe e-mails, die u naar believen kunt opstellen, zoals de volgende schermafbeelding:

Methode 3: Gebruik "OpenSharedItem" in VBA

1. Kopieer, net als bij methode 2, de volgende VBA-codes naar een andere module.

Sub ImportAllOutlookEmailsfromLocaltoOutlook2()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
    Dim objCopiedItem As Outlook.MailItem

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
 
        If strFileType = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)
           'Only import emails
           If TypeOf objItem Is MailItem Then
              Set objCopiedItem = objItem.Copy
              objCopiedItem.Move objTargetFolder
              'Delete the source file in the Windows folder
              'objFileSystem.DeleteFile (objFile.Path)
           End If
       End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

2. Voer deze macro vervolgens uit door op de toets "F5" te drukken.
3. Selecteer vervolgens de bronmap.
4. Uiteindelijk worden alle e-mails geïmporteerd als de onderstaande afbeelding:

vergelijkingen

Middelen om PST-gegevensbeschadiging te blokkeren

Zoals we allemaal weten, is Outlook vooraf geïnstalleerd met een ingebouwde tool - scanpstMeestal is het in staat om kleine problemen op te lossen. Als de problemen echter zeer ernstig zijn, zal de ingebouwde tool vaak tekortschieten. In dat geval kunt u beter een krachtigere tool gebruiken, zoals... DataNumen Outlook Repair.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder SQL Server corruptie en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com