2 manieren om snel meerdere Word-documenten samen te voegen tot één via VBA

Word-oplossingen 28 september 2025

In dit artikel delen we graag twee manieren met u om snel meerdere Word-documenten samen te voegen tot één via VBA.

In Word is er de standaard ingebouwde functie om de gebruiker te helpen bij het combineren of samenvoegen van verschillende documenten tot één document. Details worden in dit artikel uitgelegd: Meerdere Word-documenten combineren en samenvoegen tot éénMeerdere Word-documenten samenvoegen tot één

Met die methode moet je een paar klikken maken en de inhoud van het volgende document komt altijd direct na die van het vorige. Daarom willen we u snellere manieren bieden om dit te doen.

Methode 1: voeg geselecteerde documenten samen tot één

  1. Maak allereerst een nieuw, leeg document aan.
  2. Activeer de VBA-editor in Word door op "Alt + F11" te drukken.
  3. Klik vervolgens op "Normaal".
  4. Klik vervolgens op "Invoegen".
  5. En kies "Module".Klik op "Normaal" -> Klik op "Invoegen" -> Klik op "Module"
  6. Dubbelklik op nieuwe module om de bewerkingsruimte te openen.
  7. Plak daar de volgende macro:
Sub MergeMultiDocsIntoOne()
  Dim dlgFile As FileDialog
  Dim nTotalFiles As Integer
  Dim nEachSelectedFile As Integer

  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    .AllowMultiSelect = True
    If .Show <> -1 Then
      Exit Sub
    Else
      nTotalFiles = .SelectedItems.Count
    End If
  End With
 
  For nEachSelectedFile = 1 To nTotalFiles
    Selection.InsertFile dlgFile.SelectedItems.Item(nEachSelectedFile)
    If nEachSelectedFile < nTotalFiles Then
      Selection.InsertBreak Type:=wdPageBreak
    Else
      If nEachSelectedFile = nTotalFiles Then
        Exit Sub
      End If
    End If
  Next nEachSelectedFile
End Sub
  1. Klik vervolgens op "Uitvoeren" of druk op "F5".Plak Macro-> Klik op "Uitvoeren"
  2. Selecteer nu in het venster "Bladeren" meerdere bestanden door op "Ctrl" te drukken en klik op "OK".Selecteer Bestanden->Klik op "OK"
  3. Vervolgens worden alle inhoud van de geselecteerde bestanden samengevoegd in het nieuwe document, waarbij de teksten van elk document op een nieuwe pagina beginnen.

Opmerking:

Zoals we al zeiden, plaatst deze macro de teksten van elk document op een nieuwe pagina. Maar als u wilt dat ze de een na de ander zijn, kunt u enkele coderegels in de macro wijzigen. Zoek gewoon de regel "If nEachSelectedFile < nTotalFiles Then", en verwijder deze en ook de volgende zes regels.

Methode 2: voeg alle documenten in een map samen tot één

Als u een map met bestanden heeft die u wilt combineren, dan zal deze macro prachtig werken.

  1. Installeer en voer om te beginnen de macro uit zoals beschreven in methode 1.
  2. Vervang vervolgens de macro door deze:
Sub MergeFilesInAFolderIntoOneDoc()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder As String, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      .InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
End Sub
  1. Voer de macro uit door op "Uitvoeren" te klikken.
  2. Vervolgens ziet u het venster "Bladeren" geopend. Selecteer de map waarin u alle documenten opslaat. En klik op "OK".

Ook de tekst van elk document begint op een nieuwe pagina. Om ervoor te zorgen dat de tekstblokken aan elkaar vastzitten, zoek en verwijder de coderegel “.InsertBreak Type:=wdPageBreak”.

Bescherm uw Word-document goed

Een van de beste manieren om uw Word-documenten te beschermen, is door er regelmatig een back-up van te maken. Met back-ups in de hand hoeft u nooit bang te zijn voor gegevensverlies. Daarnaast is het ook aan te raden om een ​​tool aan te schaffen reparatie docx als een van hen wordt beschadigd.

Auteur Introductie:

Vera Chen is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder beschadigde Excel en pdf reparatie softwareproducten. Voor meer informatie bezoek www.datanumen.com

Reacties zijn gesloten.