2 manieren om de lijsten met Outlook-taken met verschillende categorieën op verschillende pagina's af te drukken

Als u verschillende kleurcategorieën aan uw Outlook-taken heeft toegewezen en nu de lijsten met taken met verschillende categorieën op verschillende pagina's wilt afdrukken, kunt u dit artikel raadplegen. Hier zullen we u 2 methoden delen om het te krijgen.

Om uw taken te classificeren en goed te beheren, heeft u misschien kleurcategorieën op uw taken toegepast. Als u nu de lijsten met uw taken met verschillende categorieën op verschillende pagina's wilt afdrukken, lees dan verder. In het volgende zullen we u 2 manieren voorstellen om het te krijgen.

Methode 1: Takenlijsten handmatig één voor één afdrukken

1. Open eerst in Outlook het deelvenster "Taken".
2. Open vervolgens een taakmap.
3. Druk vervolgens op "Ctrl + E" om het lint "Zoeken" te activeren.
4. Klik daarna op het tabblad "Zoeken" op de knop "Categoriseren".
5. Kies een kleurcategorie in de vervolgkeuzelijst.
6. Dan blijven alleen de taken met de geselecteerde categorie in de lijst staan.
7. Ga nu naar "Bestand"> "Afdrukken" om deze takenlijst af te drukken.
8. Druk vervolgens op dezelfde manier handmatig de takenlijsten met de andere kleurcategorieën af.

Methode 2: Batch Druk de takenlijsten af ​​op VBA

1. Activeer vanaf het begin de VBA-editor in overeenstemming met "Hoe u VBA-code in uw Outlook uitvoert'.
2. Voeg vervolgens de verwijzing naar de "MS Excel-objectbibliotheek" toe zoals beschreven in "Hoe voeg je een verwijzing naar een objectbibliotheek toe in VBA?'.
3. Kopieer vervolgens de volgende VBA-code naar een module.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Druk daarna op de toets "F5" om deze macro meteen uit te voeren.
5. Wanneer de macro is voltooid, worden de lijsten met taken met verschillende categorieën op verschillende pagina's afgedrukt, zoals weergegeven in de volgende schermafbeelding.

Krijg waardevolle gegevens terug uit een gecompromitteerd PST-bestand

Als u onderhevig bent aan een ontoegankelijk PST-bestand, is uw volgende stap ongetwijfeld PST-reparatie. In dit geval kunt u eerst de reparatietool voor inbox proberen. Als het niet lukt, kunt u doorgaan met het proberen van een andere externe tool, zoals DataNumen Outlook Repair. Het is in staat om PST-gegevens in korte tijd te herstellen.

Auteur Introductie:

Shirley Zhang is een expert op het gebied van gegevensherstel in DataNumen, Inc., de wereldleider in technologieën voor gegevensherstel, waaronder herstel mdf en Outlook-reparatiesoftwareproducten. Voor meer informatie bezoek www.datanumen.com