Cara Mencetak Semua Fail Dengan Cepat di a Zip Lampiran E-mel Outlook

Ramai pengguna berharap dapat mencetak semua fail yang dimampatkan dalam zip lampiran e-mel Outlook tanpa menyimpan dan menyahmampatkan masalah zip lampiran. Oleh itu, artikel ini akan memperkenalkan kaedah yang jauh lebih berkesan untuk merealisasikannya.

Semasa anda mahu mencetak a zip lampiran, anda mungkin biasa meletakkannya di atasnya dan mengklik butang "Cetak Pantas" dalam reben. Walau bagaimanapun, dengan cara ini, Outlook masih akan meminta anda menyimpan dan membuka zipnya terlebih dahulu. Jika anda ingin mengelakkan langkah-langkah yang menjengkelkan ini, anda boleh menggunakan kod VBA berikut.

Cetak Semua Fail dalam a Zip Lampiran E-mel

1. Untuk bermula, mulakan aplikasi Outlook anda.
2. Kemudian, dapatkan akses ke Outlook VBA editor dengan mengikuti langkah-langkah yang ditunjukkan dalam artikel - “Cara Menjalankan Kod VBA di Outlook Anda".
3. Seterusnya, anda boleh membuka projek "ThisOutlookSession" atau modul yang tidak digunakan.
4. Selepas itu, salin dan tampal kod VBA di bawah.

Dim objShell As Object
Dim objFileSystem As Object

Sub PrintAllFilesInZipAttachment ()
    Dim objAttachmentSelection As Outlook.AttachmentSelection
    Dim objAttachment, objTempAttachment As Outlook.Attachment
    Dim strTempFolder As String
    Dim strSavingPath As String
    Dim objTempMail As Outlook.MailItem
    Dim strFileName As String
 
    'Get selected attachment
    Set objAttachmentSelection = Outlook.Application.ActiveExplorer.AttachmentSelection
    Set objAttachment = objAttachmentSelection.Item(1)

    If Right(LCase(objAttachment.filename), 3) = "zip" Then
 
       'Save & Unzip the zip attachment
       Set objShell = CreateObject("Shell.Application")
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
       strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Unzip" & Format(Now, "yyyymmddhhmmss")
       MkDir (strTempFolder)
 
       strSavingPath = strTempFolder & "\" & objAttachment.filename
       objAttachment.SaveAsFile (strSavingPath)
       objShell.NameSpace((strTempFolder)).CopyHere objShell.NameSpace((strSavingPath)).Items
  
       'Attach Unzipped files to a temp mail
       Set objTempMail = Outlook.Application.CreateItem(olMailItem)
       objTempMail.Display
       strFileName = Dir(strTempFolder & "\")
 
       While Len(strFileName) > 0
             objTempMail.Attachments.Add (strTempFolder & "\" & strFileName)
             strFileName = Dir()
       Wend
 
       'Print all attachments of the temp email
       Call PrintFiles(objTempMail)
 
       objTempMail.Close olDiscard
 
       objFileSystem.DeleteFolder (strTempFolder)
    End If
End Sub

Sub PrintFiles(ByVal objMail As Outlook.MailItem)
    Dim objAttachment As Outlook.Attachment
    Dim strTempFolder, strFilePath As String
    Dim objTempFolder As Object
    Dim objTempFolderItem As Object
 
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\TEMP" & Format(Now, "yyyymmddhhmmss")
    MkDir (strTempFolder)
 
    'Print all attachments
    For Each objAttachment In objMail.Attachments
        If Right(LCase(objAttachment.filename), 3) <> "zip" Then
           strFilePath = strTempFolder & "\" & objAttachment.filename
           objAttachment.SaveAsFile (strFilePath)
 
           Set objShell = CreateObject("Shell.Application")
           Set objTempFolder = objShell.NameSpace(0)
           Set objTempFolderItem = objTempFolder.ParseName(strFilePath)
           objTempFolderItem.InvokeVerbEx ("print")
        End If
    Next
 
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Selepas itu, tutup tetingkap editor VBA semasa.
6. Kemudian, pergi ke Pilihan Outlook untuk menambahkan makro baru ke Bar Alat Akses Pantas.
7. Akhirnya, anda boleh mengambil gambar:

• Pertama, pilih a zip lampiran e-mel.
• Kemudian, klik makro di Bar Alat Akses Pantas.

8. Sekaligus, fail memampatkan dalam pilihan zip lampiran akan dicetak.

Sandarkan Fail Data Outlook

Anda mungkin mendapati bahawa Outlook mudah rosak. Sebaik sahaja Outlook rosak, data Outlook anda akan hilang. Oleh itu, adalah penting untuk membuat sandaran fail data Outlook anda secara berkala, supaya anda boleh mendapatkan semula data Outlook dengan mudah melalui sandaran. Tetapi, jika anda mendapati sandaran itu telah berusia beberapa minggu dan tidak berkesan, anda tidak mempunyai pilihan selain menggunakan perkhidmatan yang boleh dipercayai dan berpengalaman. Pemulihan PST alat, seperti DataNumen Outlook Repair.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk mdf rosak dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com