Cara Cepat Mengeksport Folder Outlook dengan Semua Subfolder & Item ke Folder Windows

Kadang-kadang, anda mungkin ingin mengeksport secara berkumpulan folder Outlook dengan semua subfolder dan item ke folder Windows. Artikel ini akan mengajar anda kaedah seperti yang menerapkan Outlook VBA.

Apabila anda ingin mengeksport folder Outlook ke pemacu tempatan dengan semua item dalam struktur folder yang sama, jika anda memilih untuk menyimpan dan mengeksport secara manual, anda memerlukan banyak masa. Oleh itu, mengapa anda tidak menggunakan kaedah lain, seperti alat eksport atau kod VBA? Di sini kami akan memperkenalkan sekeping kod VBA seperti itu kepada anda. Ini akan membolehkan anda mencapainya seperti angin.

Eksport Semua Subfolder & Item dalam Folder Outlook ke Folder Windows

1. Pada mulanya, mulakan program Outlook anda.
2. Kemudian di tetingkap Outlook utama, tekan pintasan kekunci "Alt + F11".
3. Selanjutnya, tetingkap "Microsoft Visual Basic for Applications" akan muncul.
4. Seterusnya anda perlu membuka modul kosong dan menyalin kod VBA berikut ke dalamnya.

Private objFileSystem As Object
 
Private Sub ExportFolderWithAllItems()
    Dim objFolder As Outlook.Folder
    Dim strPath As String
 
    'Specify the root local folder
    'Change it as per your needs
    strPath = "E:\Outlook\"
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    'Select a Outlook PST file or Outlook folder
    Set objFolder = Outlook.Application.Session.PickFolder
 
    Call ProcessFolders(objFolder, strPath)
 
    MsgBox "Complete", vbExclamation
End Sub
 
Private Sub ProcessFolders(objCurrentFolder As Outlook.Folder, strCurrentPath As String)
    Dim objItem As Object
    Dim strSubject, strFileName, strFilePath As String
    Dim objSubfolder As Outlook.Folder
 
    'Create the local folder based on the Outlook folder
    strCurrentPath = strCurrentPath & objCurrentFolder.Name
    objFileSystem.CreateFolder strCurrentPath
 
    For Each objItem In objCurrentFolder.Items
 
        strSubject = objItem.Subject
 
        'Remove unsupported characters in the subject
        strSubject = Replace(strSubject, "/", " ")
        strSubject = Replace(strSubject, "\", " ")
        strSubject = Replace(strSubject, ":", "")
        strSubject = Replace(strSubject, "?", " ")
        strSubject = Replace(strSubject, Chr(34), " ")

        strFileName = strSubject & ".msg"
 
        i = 0
        Do Until False
           strFilePath = strCurrentPath & "\" & strFileName
           'Check if there exist a file in the same name
           If objFileSystem.FileExists(strFilePath) Then
              'Add a sequence order to the file name
              i = i + 1
              strFileName = strSubject & " (" & i & ").msg"
           Else
              Exit Do
          End If
        Loop
 
        'Save as MSG file
        objItem.SaveAs strFilePath, olMSG
    Next
 
    'Process subfolders recursively
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder, strCurrentPath & "\")
       Next
    End If
End Sub

5. Selepas itu, anda perlu memastikan bahawa Outlook anda membenarkan makro dalam tetapan makro.
6. Akhirnya, anda boleh mencuba.

• Pertama, kembali ke tetingkap makro baru.
• Klik seterusnya ke subrutin "ExportFolderWithAllItems".
• Kemudian tekan butang kekunci F5 untuk menjalankan makro ini.
• Selepas itu, anda perlu memilih folder tertentu.
• Terakhir, apabila anda mendapat mesej yang mengatakan "Selesai", anda boleh mengakses folder tempatan yang telah ditentukan. Anda akan dapati semua item telah disimpan dalam struktur folder yang sama.

Mencegah Kehilangan Data dari Kerosakan Outlook

Mungkin anda pernah mengalami banyak masalah Outlook. Kebanyakan masa, selepas dimulakan semula, Outlook akan dapat berfungsi seperti biasa. Walau bagaimanapun, terdapat juga kes di mana fail PST kita mungkin rosak. Pada masa itu, anda akan cuba sedaya upaya untuk mendapatkan semula data PST anda, seperti berulang kali menggunakan alat yang berpengalaman seperti DataNumen Outlook Repair. Ia mampu betulkan Outlook kesilapan dan ekstrak data dari fail PST yang dikompromikan tanpa berpeluh.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk SQL Server pembaikan dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com