Cara Menetapkan Waktu Peringatan Lalai yang Berbeza untuk Berbagai Jenis Item yang Dilanda di Outlook Anda

Secara lalai, Outlook akan secara automatik menggunakan waktu peringatan lalai tugas untuk semua jenis item yang ditandai. Namun, jika anda ingin menggunakan waktu peringatan yang berlainan untuk item yang ditandai berdasarkan jenis item, Anda dapat merujuk pada metode yang diperkenalkan dalam artikel ini.

Outlook membolehkan anda menetapkan waktu peringatan lalai untuk semua item yang ditandai, tanpa mengira jenis item. Anda boleh pergi ke menu "File" dan klik "Options". Kemudian, di tetingkap "Opsi Outlook", Anda dapat melihat opsi "Waktu peringatan lalai" pada tab "Tugas", seperti yang ditunjukkan pada tangkapan layar berikut.

Walau bagaimanapun, kebanyakan pengguna berharap untuk menggunakan masa peringatan yang berbeza untuk pelbagai jenis item yang ditandai, seperti "9:00" untuk mel yang ditandai dan "17:30" untuk kenalan yang ditandai. Sekarang, dalam perkara berikut, kami akan menumpukan pada contoh ini untuk memperkenalkan satu kaedah.

Tetapkan Masa Peringatan Lalai yang Berbeza untuk Berbagai Jenis Item yang Dibenderakan

1. Untuk bermula, lancarkan aplikasi Outlook.
2. Kemudian, akses editor Outlook VBA dengan merujuk kepada “Cara Menjalankan Kod VBA di Outlook Anda".
3. Di tetingkap "Microsoft Visual Basic for Applications" berikutnya, salin kod berikut ke dalam proyek "ThisOutlookSession".

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Selepas itu, mulakan semula Outlook untuk mengaktifkan makro ini.
5. Mulai sekarang, setiap kali anda menandai e-mel, waktu peringatan akan ditetapkan ke "10:00" pada tarikh jatuh tempo bendera.
6. Dan apabila anda menandakan kenalan, waktu peringatan akan ditetapkan ke "17:30" pada tarikh bendera.

Atasi Masalah Outlook Secara Fleksibel

Anda boleh menghadapi pelbagai jenis masalah dalam Outlook anda. Jadi, anda perlu mempelajari beberapa langkah untuk menanganinya terlebih dahulu. Contohnya, jika Outlook anda kerap dimulakan semula, anda perlu membaiki Office atau melumpuhkan alat tambah pihak ketiga, dsb. Atau jika Outlook PST anda terjejas, anda boleh mencubanya terlebih dahulu. alat pembaikan peti masuk. Apabila gagal, anda boleh terus menggunakan alat luaran yang hebat, seperti DataNumen Outlook Repair.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pemulihan mdf dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com