Cara Menggunakan Warna Font yang Berbeza secara automatik untuk Membalas dan Memajukan E-mel dengan Outlook VBA

Secara lalai, anda tidak boleh membiarkan Outlook menggunakan warna font yang berbeza secara automatik untuk membalas dan meneruskan e-mel. Oleh itu, jika anda mempunyai syarat seperti itu, anda boleh membaca halaman iniost untuk belajar pendekatan pintar.

Outlook hanya membenarkan anda menentukan fon yang digunakan untuk membalas dan meneruskan e-mel. Anda boleh pergi ke "Fail"> "Pilihan". Kemudian, dalam "Pilihan Outlook", beralih ke tab "Mel" dan klik butang "Alat Tulis dan Fon ...". Di tetingkap berikutnya, anda dapat melihat butang "Font" di "Membalas atau meneruskan mesej". Klik, dan kemudian anda boleh menetapkan warna fon tertentu untuk membalas dan meneruskan e-mel.

Namun, banyak pengguna berharap dapat menggunakan warna fon yang berbeza untuk membalas atau meneruskan e-mel. Walaupun Outlook tidak menyediakan ciri langsung untuk ini, ia masih dapat dilaksanakan dengan kod VBA. Sekarang, baca terus untuk mendapatkan sekeping kod VBA.

Auto Menggunakan Warna Fon yang berbeza untuk Membalas dan Mengirim E-mel

1. Untuk sebagaitart, lancarkan aplikasi Outlook.
2. Kemudian, cetuskan editor VBA dengan merujuk kepada "Cara Menjalankan Kod VBA di Outlook Anda".
3. Selanjutnya, sesuai dengan "Bagaimana Menambah Objek Library Rujukan dalam VBA", Tambahkan rujukan ke" MS Word Object Library ”.
4. Selepas itu, salin kod berikut ke dalam projek "ThisOutlookSession".

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

5. Selepas itu, restart Outlook untuk mengaktifkan makro ini.
6. Akhirnya, anda boleh mencuba.

• Pilih atau buka e-mel.
• Kemudian, klik butang "Balas". Dalam membalas e-mel, anda boleh memasukkan beberapa perkataan dalam badan. Warna fon mestilah berwarna merah jambu.
• Atau klik butang "Balas Semua". Dalam mel "membalas semua" baru, masukkan kata-kata dalam badan. Warna fon pasti berwarna hijau.
• Begitu juga, klik butang "Teruskan". Dalam surat pemajuan, perkataan baru akan ditunjukkan dengan warna biru.

Gunakan Perisian yang Boleh Dipercayai

Sekiranya berlaku Rasuah Outlook, most pengguna cenderung menggunakan perisian pemulihan Outlook. Terdapat sebilangan besar program sedemikian yang terdapat di pasaran. Malah ada di antaranya percuma. Walaupun begitu, anda harus berhati-hati dengan orang-orang dari sumber yang tidak diketahui kerana mereka boleh menjadikan kes semasa menjadi lebih buruk dan buruk. Anda harus menggunakan alat yang boleh dipercayai dan berpengalaman, seperti DataNumen Outlook Repair.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk sql rosak dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com