Cara Menghapus E-mel Outlook secara automatik dari Pengirim Tertentu setelah Hari Tertentu

Untuk membiarkan Outlook anda secara automatik menghapus e-mel dari pengirim tertentu dari hari-hari tertentu, anda boleh membaca artikel ini. Di sini kami akan menunjukkan kepada anda langkah-langkah terperinci untuk menggunakan kod VBA untuk mendapatkannya.

Ketika berkaitan dengan penghapusan e-mel secara automatik, pertama-tama anda mungkin memikirkan ciri "AutoArchive". Namun, tidak dapat menyaring pengirim tertentu ketika mengarkibkan e-mel secara automatik. Oleh itu, sebagai contoh, jika anda ingin memadam e-mel secara automatik dari pengirim tertentu setelah x hari, anda harus menggunakan cara lain, seperti yang berikut.

Hapus E-mel secara automatik dari Pengirim Tertentu selepas X Hari

1. Pada mulanya, mulakan aplikasi Outlook anda.
2. Kemudian, cetuskan editor Outlook VBA mengikut “Cara Menjalankan Kod VBA di Outlook Anda".
3. Seterusnya, salin kod VBA berikut ke dalam projek "ThisOutlookSession".

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
 
    Call DeleteEmailsFromSpecificSenderAfterXDays
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'From the specific sender
       If objMail.SenderEmailAddress = "bob_black@datanumen.com" Then
          'Set expiry time - after 5 days
          objMail.ExpiryTime = objMail.ReceivedTime + 4
          objMail.Save
       End If
    End If
End Sub

Private Sub DeleteEmailsFromSpecificSenderAfterXDays()
    Dim strFilter As String
    Dim objExpiredItems As Outlook.Items
    Dim objExpiredMail As Outlook.MailItem
 
    strFilter = "[ExpiryTime] <= " & Chr(34) & Now & Chr(34)
 
    'Get all expired items
    Set objExpiredItems = objInboxItems.Restrict(strFilter)
 
    For i = objExpiredItems.Count To 1 Step -1
        If objExpiredItems(i).Class = olMail Then
           Set objExpiredMail = objExpiredItems(i)
 
           'Auto delete expired emails from the specific sender
           If objExpiredMail.SenderEmailAddress = "bob_black@datanumen.com" Then
              objExpiredMail.Delete
           End If
        End If
    Next
End Sub

4. Selepas itu, mulakan semula Outlook untuk mengaktifkan makro ini.
5. Sejak itu, setiap kali e-mel baru dari pengirim tertentu tiba di Peti Masuk, ia akan diberikan dengan waktu luput tertentu - hari-hari tertentu setelah diterima.
6. Kemudian, setiap kali anda memulakan Outlook, Outlook akan menyemak dan memadam mel yang telah tamat tempoh daripada penghantar tertentu secara automatik.

Pulihkan Data Outlook selepas Rasuah

Mungkin anda telah menghadapi pelbagai kesalahan dan masalah di Outlook. Kemudian, pernahkah anda menghadapi kerosakan Outlook? Contohnya, jika anda sering keluar dari Outlook dengan tidak betul, fail PST anda cenderung rosak. Secara amnya, dalam kes seperti itu, anda dapat memilih untuk mengambil data Outlook dari sandaran. Atau anda boleh menggunakan alat pembaikan peti masuk atau alat luaran yang boleh dipercayai, seperti DataNumen Outlook Repair.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pulihkan sql dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com