Cara Batch Simpan Beberapa E-mel Draf sebagai Templat Outlook

Mungkin anda telah membuat beberapa draf e-mel dan berharap dapat menggunakannya semula banyak kali. Jika demikian, mengapa Anda tidak menyimpannya secara batch sebagai templat Outlook? Artikel ini akan mengajar anda untuk mencapainya dalam satu masa melalui VBA.

Secara lalai, Outlook hanya membenarkan pengguna menyimpan satu e-mel sebagai templat sekaligus. Dengan kata lain, anda tidak dapat menyimpan banyak draf e-mel sebagai templat secara pukal. Seperti yang anda lihat, ketika Anda memilih lebih dari satu e-mel dan pergi ke "File"> "Save As", Anda tidak dapat menemukan format "Templat Outlook" dalam daftar "Simpan sebagai jenis", hanya "Teks Saja" yang tersedia. Tetapi, kami akan memperkenalkan kepada anda bagaimana untuk mewujudkannya secara besar-besaran berikut.

Batch Save Multiple Draf Email sebagai Templat Outlook

1. Pada awalnya, cetuskan penyunting Outlook VBA.
2. Di tetingkap "Microsoft Visual Basic for Applications" yang baru, salin dan tampal kod VBA di bawah.

Sub SaveMultipleDraftsAsTemplates()
    Dim objSelection As Outlook.Selection
    Dim i As Long
    Dim strTemplateFolder As String
    Dim objMail As Outlook.MailItem
    Dim strSubject As String
 
    'Get all selected mails
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
       'Get the default folder for saving Outlook Templates
       strTemplateFolder = CStr(Environ("USERPROFILE")) & "\Documents\UserTemplates\"
 
       'Save each mail as template
       For i = objSelection.Count To 1 Step -1
           If objSelection(i).Class = olMail Then
              Set objMail = objSelection(i)
              If objMail.Subject <> "" Then
 
                 'Remove unsupported characters
                 strSubject = objMail.Subject
                 strSubject = Replace(strSubject, "/", " ")
                 strSubject = Replace(strSubject, "\", " ")
                 strSubject = Replace(strSubject, ":", "")
                 strSubject = Replace(strSubject, "?", " ")
                 strSubject = Replace(strSubject, Chr(34), " ")
 
                 objMail.SaveAs strTemplateFolder & strSubject & ".oft", olTemplate
              Else
                 objMail.SaveAs strTemplateFolder & "Template" & i & ".oft", olTemplate
              End If
           End If
       Next
 
       'Open the folder of Templates
       Shell "Explorer.exe" & " " & strTemplateFolder, vbNormalFocus
    End If
End Sub

3. Selepas itu, untuk kemudahan di kemudian hari, disarankan untuk melampirkan makro ini ke Quick Access Toolbar (QAT). Mengenai langkah terperinci, anda boleh membaca “Cara Menjalankan Kod VBA di Outlook Anda"
4. Pada akhirnya, anda boleh mengambil gambar dengan mengikuti operasi di bawah.

• Pada mulanya, pilih draf e-mel yang akan disimpan sebagai templat.
• Kemudian, klik butang makro di QAT.
• Apabila makro selesai, folder Windows untuk menyimpan templat Outlook lalai akan dipaparkan. Anda dapat melihat bahawa templat dari e-mel draf yang dipilih ada di sana.

Alat Pembaikan Peti Masuk Masih Gagal

Apabila menggunakan alat pembaikan Outlook dalaman - Scanpst, sebilangan besar pengguna akan sangat menghargainya. Tidak dinafikan, utiliti ini memang mampu menyelesaikan sebahagian besar masalah kecil di Outlook. Namun, ia sama sekali tidak sempurna. Ia masih boleh gagal dan menimbulkan banyak kesalahan. Contohnya, sekiranya berlaku teruk Rasuah Outlook, ia tidak dapat membaiki fail PST yang dikompromikan. Dalam senario itu, anda tidak mempunyai alaternatif melainkan menggunakan alat pihak ketiga yang hebat dan hebat, seperti DataNumen Outlook Repair.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pemulihan sql dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com