Cara Auto Mengeksport Maklumat E-mel Masuk ke Fail Excel dengan Outlook VBA

Ramai pengguna berharap Outlook dapat mengeksport maklumat utama e-mel masuk ke fail Excel secara automatik. Artikel ini akan melihat keperluan ini dan memperkenalkan kaedah cepat melalui Outlook VBA.

Kadang-kadang, untuk beberapa sebab, seperti statistik e-mel, anda mungkin sering perlu mengeksport e-mel ke fail Excel. Secara amnya, untuk e-mel yang sudah ada, anda hanya dapat menggunakan fitur "Import dan Export" untuk mengeksportnya ke Excel dalam satu perjalanan. Namun, mungkin anda mahu Outlook dapat mengeksport e-mel masuk ke Excel secara automatik sebaik sahaja mereka tiba di peti mel anda. Tanpa keraguan, tidak ada ciri asli seperti itu di Outlook. Oleh itu, anda perlu menggunakan pendekatan lain, seperti add-in pihak ketiga atau Outlook VBA. Di sini kami akan mengajar anda bagaimana membuatnya secara automatik dengan Outlook VBA. Baca terus untuk mendapatkan langkah-langkah dan mengikut kod.

Maklumat Eksport Auto E-mel Masuk ke Fail Excel

1. Pertama, anda harus membuat fail Excel.

• Buka fail Excel baru.
• Maka anda harus menaip "Tidak." di Sel A1, "Nama Pengirim" di Sel B1, "Alamat Pengirim Email" di Sel C1, dan "Subjek E-mel" di Sel D1, dan "Waktu Diterima" di Sel E1, seperti gambar berikut.
• Akhir sekali simpan di nama dan folder yang anda mahukan.

2. Selepas itu, anda harus melancarkan Outlook.
3. Kemudian tekan butang kekunci "Alt + F11", yang akan membawa anda ke editor VBA.
4. Seterusnya di tetingkap pop timbul, anda harus mengklik dua kali "ThisOutlookSession" di sebelah kiri.
5. Selepas itu, dalam tetingkap projek "ThisOutlookSession", anda perlu menyalin dan menempelkan kod VBA berikut ke dalamnya.

Public WithEvents objMails As Outlook.Items

Private Sub Application_Startup()
    Set objMails = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub objMails_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim strColumnB As String
    Dim strColumnC As String
    Dim strColumnD As String
    Dim strColumnE As String

    If Item.Class = olMail Then
       Set objMail = Item
    End If
 
    'Specify the Excel file which you want to auto export the email list
    'You can change it as per your case
    strExcelFile = "E:\Email\Email Statistics.xlsx"
 
    'Get Access to the Excel file
    On Error Resume Next
    Set objExcelApp = GetObject(, "Excel.Application")
    If Error <> 0 Then
       Set objExcelApp = CreateObject("Excel.Application")
    End If
    Set objExcelWorkBook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorkSheet = objExcelWorkBook.Sheets("Sheet1")
 
    'Get the next empty row in the Excel worksheet
    nNextEmptyRow = objExcelWorkSheet.Range("B" & objExcelWorkSheet.Rows.Count).End(xlUp).Row + 1
 
    'Specify the corresponding values in the different columns
    strColumnB = objMail.SenderName
    strColumnC = objMail.SenderEmailAddress
    strColumnD = objMail.Subject
    strColumnE = objMail.ReceivedTime
 
    'Add the vaules into the columns
    objExcelWorkSheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorkSheet.Range("B" & nNextEmptyRow) = strColumnB
    objExcelWorkSheet.Range("C" & nNextEmptyRow) = strColumnC
    objExcelWorkSheet.Range("D" & nNextEmptyRow) = strColumnD
    objExcelWorkSheet.Range("E" & nNextEmptyRow) = strColumnE
 
    'Fit the columns from A to E
    objExcelWorkSheet.Columns("A:E").AutoFit
 
    'Save the changes and close the Excel file
    objExcelWorkBook.Close SaveChanges:=True
End Sub

6. Nanti anda mesti menandatangani kod ini.
7. Selepas itu, restart Outlook untuk mengaktifkan projek VBA baru.
8. Akhirnya, mulai sekarang, semua e-mel yang masuk akan dieksport secara automatik ke fail Excel yang telah ditetapkan sebaik sahaja masuk ke folder Peti Masuk anda. Fail excel akan kelihatan seperti gambar berikut:

Mengelakkan Rasuah Data PST yang Menyakitkan

Outlook telah mendapat banyak pujian kerana pelbagai ciri. Namun, itu tidak bermaksud perkara itu sangat mudah. Ia masih boleh dikompromikan pada bila-bila masa. Sebagai contoh, jika anda sering menutup Outlook dengan tidak betul, sangat mungkin data PST anda berada dalam bahaya. Dalam kes ini, jika anda mahu membaiki PST data, anda mesti menggunakan alat yang berpengalaman, seperti DataNumen Outlook Repair.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pulih mdf dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com