3 Kaedah Pantas untuk Menghapus Baris dan Lajur Kosong dalam Jadual Word Anda

Dalam hlm iniost, kami akan menerangkan kepada anda 3 cara cepat untuk menghapus baris dan lajur kosong di jadual Word anda.

Jadual sangat penting untuk dokumen, terutama dalam menyimpan pelbagai jenis data. Kadang-kadang, jadual panjang boleh melebihi satu halaman dan merangkumi beberapa halaman. Oleh itu, apabila jadual menjadi panjang dan rumit, ada langkah-langkah yang boleh anda lakukan untuk mempermudahnya. Contohnya, anda boleh menghapus baris dan lajur kosong yang tidak diperlukan.

Berikut adalah 3 kaedah yang boleh anda gunakan.

Kaedah 1: Padam Baris dan Lajur Kosong Secara Manual

1. Pertama, pilih baris atau lajur kosong.
2. Kemudian klik kanan untuk mendapatkan menu kontekstual. Pada menu, pilih "Hapus Baris" atau "Hapus Lajur" yang sesuai.

Malangnya, anda tidak dapat memilih beberapa baris atau lajur yang tidak berturut-turut dan menghapusnya bersama-sama dengan cara ini. Untuk permintaan ini, anda boleh merujuk pada artikel kami sebelumnya: 5 Kaedah Pantas untuk Menghapus Banyak Baris atau Lajur dalam Jadual Kata Anda

Kaedah 2: Padam Batch Semua Baris dan Lajur Kosong dalam Jadual

Kaedah 1 mempunyai hadnya. Oleh itu, kami akan memberi anda cara untuk mengumpulkan baris dan lajur secara berkumpulan dalam jadual melalui kod VBA.

1. Sebagai permulaan, masukkan kursor di dalam a tardapatkan meja.
2. Kedua, cetuskan editor VBA dengan menekan "Alt + F11".
3. Di editor, klik projek "Normal" terlebih dahulu.
4. Kemudian klik tab "Masukkan" pada bar menu.
5. Pada menu lungsur turun, pilih "Modul".
6. Klik dua kali pada modul untuk membukanya dan tampal kod berikut di sana:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Akhirnya, klik butang "Jalankan" pada bar menu atau tekan "F5".

Dalam beberapa saat, anda akan membuang semua baris dan lajur kosong dalam jadual tersebut.

Kaedah 3: Hapus Kumpulan Semua Baris dan Lajur Kosong di Semua Jadual dalam Dokumen

1. Pertama, ulangi langkah dalam kaedah 2 untuk memasang dan menjalankan makro.
2. Hanya kali ini, ganti makro itu dengan yang berikut:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Pulihkan Dokumen Rosak

Terdapat lebih daripada satu kaedah untuk mendapatkan semula lost data kembali pada masa kini. Contohnya, menggunakan sandaran selalu menjadi keutamaan anda. Sekiranya itu tidak memenuhi keperluan anda untuk mendapatkan maklumat terkini, anda boleh mencuba a pembaikan doc alat.

Pengenalan Pengarang:

Vera Chen adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pembaikan xlsx dan pdf membaiki produk perisian. Untuk maklumat lebih lanjut, lawati www.datanumen.com