2 Cara Menggabungkan Dokumen Word Banyak dengan Satu melalui VBA

Dalam artikel ini, kami dengan senang hati berkongsi dengan anda 2 cara untuk menggabungkan beberapa dokumen Word menjadi satu melalui VBA dengan cepat.

Di Word, terdapat ciri bawaan lalai untuk membantu pengguna menggabungkan atau menggabungkan beberapa dokumen menjadi satu. Perincian dijelaskan dalam artikel ini: Cara Menggabungkan & Menggabungkan Beberapa Dokumen Word menjadi Satu

Dengan kaedah itu, anda mesti membuat beberapa klik dan kandungan dokumen seterusnya selalu datang tepat setelah yang sebelumnya. Oleh itu, kami ingin menawarkan cara yang lebih pantas untuk melakukannya.

Kaedah 1: Gabungkan Dokumen Terpilih menjadi Satu

1. Pertama sekali, buat dokumen kosong baharu.
2. Mencetuskan editor VBA di Word dengan menekan "Alt + F11".
3. Klik seterusnya "Normal".
4. Kemudian klik "Masukkan".
5. Dan pilih "Modul".
6. Klik dua kali pada modul baru untuk membuka ruang penyuntingan.
7. Tampal makro berikut di sana:

Sub MergeMultiDocsIntoOne()
  Dim dlgFile As FileDialog
  Dim nTotalFiles As Integer
  Dim nEachSelectedFile As Integer

  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    .AllowMultiSelect = True
    If .Show <> -1 Then
      Exit Sub
    Else
      nTotalFiles = .SelectedItems.Count
    End If
  End With
 
  For nEachSelectedFile = 1 To nTotalFiles
    Selection.InsertFile dlgFile.SelectedItems.Item(nEachSelectedFile)
    If nEachSelectedFile < nTotalFiles Then
      Selection.InsertBreak Type:=wdPageBreak
    Else
      If nEachSelectedFile = nTotalFiles Then
        Exit Sub
      End If
    End If
  Next nEachSelectedFile
End Sub

8. Klik seterusnya "Run" atau tekan "F5".
9. Sekarang di tetingkap "Browse", pilih beberapa fail dengan menekan "Ctrl" dan klik "OK".
10. Kemudian semua kandungan dalam fail yang dipilih akan digabungkan dalam dokumen baharu, dengan teks setiap dokumen bermula pada halaman baharu.

Catatan:

Seperti yang kami sebutkan, makro ini meletakkan teks setiap dokumen di halaman baru. Tetapi jika anda memerlukannya menjadi satu demi satu, anda boleh mengubah beberapa baris kod dalam makro. Cari baris "If nEachSelectedFile <nTotalFiles Then", hapus dan enam baris seterusnya juga.

Kaedah 2: Gabungkan Semua Dokumen dalam Folder menjadi Satu

Sekiranya anda mempunyai folder fail untuk digabungkan, makro ini akan berfungsi dengan baik.

1. Untuk bermula, pasang dan jalankan makro seperti yang diterangkan dalam kaedah 1.
2. Kemudian gantikan makro dengan yang berikut:

Sub MergeFilesInAFolderIntoOneDoc()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder As String, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      .InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
End Sub

3. Jalankan makro dengan mengklik "Jalankan".
4. Seterusnya anda melihat tetingkap "Browse" terbuka. Pilih folder tempat anda menyimpan semua dokumen. Dan klik "OK".

Begitu juga, teks setiap dokumen bermula pada halaman baharu. Untuk menjadikannya melekat bersama satu demi satu, cari dan padam baris kod “.InsertBreak Type:=wdPageBreak”.

Lindungi Dokumen Word Anda dengan betul

Salah satu kaedah terbaik untuk melindungi dokumen Word anda adalah dengan menyandarkannya secara berkala. Dengan adanya sandaran, anda tidak perlu takut kehilangan data. Selain itu, disarankan untuk mendapatkan alat untuk baiki docx sekiranya ada daripadanya akan rosak.

Pengenalan Pengarang:

Vera Chen adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk Excel rosak dan pdf membaiki produk perisian. Untuk maklumat lebih lanjut, lawati www.datanumen.com