2 Cara Pantas untuk Mencari atau Menghapus Kalimat yang Mengandungi Teks Khusus dalam Firman Anda

Dalam artikel ini, kami akan menawarkan 2 cara cepat untuk mencari atau menghapus ayat yang mengandungi teks tertentu di Word anda.

Semua orang tahu bahawa kita boleh menggunakan fungsi "Cari dan Ganti" dalam Word untuk mencari semua kemunculan perkataan tertentu dengan mudah. ​​Maka kita tidak akan menghadapi masalah untuk menyerlahkan, menggantikan atau mengalih keluarnya. Seperti yang anda lihat, sasarannya ialah perkataan atau frasa. Walau bagaimanapun, hari ini, kami dengan sukacitanya memberitahu anda cara makro untuk mencari atau memadam ayat yang mengandungi teks tertentu.

Kaedah 1: Cari atau Padamkan Kalimat yang Mengandungi Teks Tertentu

1. Sebagai permulaan, tekan "Alt + F11" untuk mencetuskan editor VBA di Word.
2. Seterusnya buat modul baru dengan mengklik "Normal".
3. Kemudian klik "Insert" dan pilih "Module" untuk mendapatkan yang baru.
4. Dan buka modul dengan klik dua kali.
5. Sekarang tampal kod berikut:

Sub DeleteSentencesContainingSpecificWords()
  Dim strTexts As String
  Dim strButtonValue As String
 
  strTexts = InputBox("Enter texts to be found here: ")
 
  With Selection
    .HomeKey Unit:=wdStory
 
    '  Find the entered texts.
    With Selection.Find
      .ClearFormatting
      .Text = strTexts
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute
    End With
 
    Do While .Find.Found = True
      '  Expand the selection to the entire sentence.
      Selection.Expand Unit:=wdSentence
      strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
      If strButtonValue = vbYes Then
        Selection.Delete
      End If
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
End Sub

6. Klik seterusnya "Run".
7. Akan ada kotak input, meminta anda memasukkan teks. Taipkan teks biasa yang mengandungi semua ayat. Klik "OK".
8. Kemudian anda akan melihat ayat yang mengandungi teks dalam pilihan dengan kotak mesej yang muncul. Klik "Ya" untuk menghapus kalimat dan "Tidak" untuk menyimpannya.
9. Selepas pengesahan, ayat seterusnya dengan teks yang ditetapkan akan dipilih. Dan terdapat juga kotak pengesahan. Iaitu, makro akan membawa anda untuk melihat keseluruhan dokumen, mencari ayat sasaran dan meminta pengesahan anda setiap kali.

Kaedah 2: Cari atau Padam Kalimat yang Mengandungi Teks dalam Senarai

Dengan makro dalam kaedah 1, anda hanya boleh mencari satu perkataan atau frasa satu masa. Sudah tentu, anda boleh menjalankan makro berulang kali untuk mencari pelbagai contoh perkataan atau frasa. Untuk memenuhi keperluan pencarian berganda, kami akan memberikan makro lain kepada anda.

1. Mula-mula letakkan semua teks sasaran pada dokumen baharu. Pastikan setiap teks menempati satu perenggan tanpa ruang di belakang. Tutup dan simpan dokumen tersebut.
2. Selanjutnya pasang dan jalankan makro dengan langkah tepat dalam kaedah 1.
3. Kemudian gantikan makro dengan yang berikut:

Sub DeleteSentencesContainingSpecificWordsOnAList()
  Dim objListDoc As Document, objTargetDoc As Document
  Dim objParaRange As Range
  Dim objParagraph As Paragraph
  Dim strFileName As String, strButtonValue As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    If .Show = -1 Then
      strFileName = .SelectedItems(1)
    Else
      MsgBox "No file is selected! Please select the target file."
      Exit Sub
    End If
  End With
  Set objTargetDoc = ActiveDocument
  Set objListDoc = Documents.Open(strFileName)
  objTargetDoc.Activate
 
  For Each objParagraph In objListDoc.Paragraphs
    Set objParaRange = objParagraph.Range
    objParaRange.End = objParaRange.End - 1
 
    With Selection
      .HomeKey Unit:=wdStory
 
      '  Find target words.
      With Selection.Find
        .ClearFormatting
        .Text = objParaRange
        .MatchWholeWord = True
        .MatchCase = False
        .Execute
      End With
 
      '  Expand the selection to the entire sentence.
      Do While .Find.Found
        Selection.Expand Unit:=wdSentence
        strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
        If strButtonValue = vbYes Then
          Selection.Delete
        End If
        .Collapse wdCollapseEnd
        .Find.Execute
      Loop
    End With
  Next objParagraph
End Sub

4. Sekarang tetingkap "Browse" akan terbuka. Pilih dokumen yang baru disimpan dan klik "Buka".
5. Prosedur berikut sama dengan kaedah 1.

Pendekatan untuk Menangani Dokumen yang Rosak

Kehilangan data berharga benar-benar dahsyat. Bahkan boleh membuat perniagaan anda dipertaruhkan. Untuk mengelakkan kekecewaan seperti itu, anda perlu memahami Pembetulan perkataan alat secepat mungkin. Alat sedemikian akan membantu anda memenangi pertempuran dengan kerosakan dokumen.

Pengenalan Pengarang:

Vera Chen adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk betulkan Excel dan pdf membaiki produk perisian. Untuk maklumat lebih lanjut, lawati www.datanumen.com