2 Kaedah untuk Menghantar Sel yang Dipilih dengan pantas dalam Lembaran Kerja Excel sebagai Email Outlook

Kongsi Sekarang:

Kadang-kadang, anda mungkin ingin memasukkan sel yang dipilih dengan cepat dalam lembaran kerja Excel ke e-mel Outlook dan menghantar e-mel ini. Artikel ini akan melihat hasrat ini untuk menawarkan anda 2 kaedah.

Artikel saya sebelum ini “2 Kaedah Pantas untuk Menghantar Lembaran Kerja Excel sebagai E-mel Outlook"Telah mengajar anda cara menghantar keseluruhan lembaran kerja Excel sebagai e-mel. Walau bagaimanapun, kadang-kadang, anda hanya ingin menghantar sel yang dipilih dalam lembaran kerja sebagai e-mel. Sebagai tindak balas kepada keperluan ini, di sini kami akan memberi anda 2 kaedah. Anda boleh memilih sama ada mengikut pilihan anda.

2 Kaedah untuk Menghantar Sel yang Dipilih dengan pantas dalam Lembaran Kerja Excel sebagai Email Outlook

Kaedah 1: Salin Sel Terpilih ke E-mel Secara Manual

  1. Untuk bermula, buka fail Excel sumber dan akses lembaran kerja Excel yang betul.
  2. Kemudian pilih sel yang ingin anda hantar sebagai e-mel Outlook.
  3. Selanjutnya tekan pintasan kekunci "Ctrl + C" untuk menyalin sel yang dipilih.Tekan pintasan kekunci "Ctrl + C" untuk menyalin sel yang dipilih
  4. Selepas itu, lancarkan aplikasi Outlook anda.
  5. Selepas itu, klik pada butang "E-mel Baru" di pita "Rumah" untuk membuat e-mel Outlook baru.
  6. Kemudian di tetingkap Mesej baru, klik ke bahagian isi mesej.
  7. Dan kemudian tekan butang kekunci "Ctrl + V" untuk menampal sel Excel yang dipilih sebelumnya yang disalin.
  8. Terakhir, anda boleh menyusun e-mel seperti biasa dan klik butang "Kirim" untuk menghantarnya.

Kaedah 2: Hantar Sel Terpilih sebagai E-mel melalui VBA

  1. Pada awalnya, buka buku kerja Excel sumber.
  2. Kemudian tekan butang kekunci "Alt + F11" untuk mengakses editor Excel VBA.
  3. Di tetingkap baru, klik "Sisipkan"> "Modul" untuk memasukkan modul baru.
  4. Seterusnya, anda perlu mendayakan Microsoft Outlook Object. Klik “Tools” > “References”. Dalam kotak dialog timbul, cari dan tandakan “Microsoft Outlook Object Library”.Aktifkan Objek Microsoft Outlook dalam Excel
  5. Selepas itu, salin kod VBA berikut ke dalam modul ini.
Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

Kod VBA - Hantar Sel Terpilih dalam Lembaran Kerja Excel sebagai E-mel Outlook

  1. Akhirnya, anda boleh mencuba.
  • Pertama, pilih sel tertentu seperti biasa.
  • Kemudian kembali ke makro baru dan tekan kekunci F5 untuk mencetuskannya.
  • Sekali gus, e-mel Outlook baru akan dipaparkan, di mana anda dapat melihat bahawa sel yang dipilih telah dimasukkan ke dalam badan e-mel, seperti tangkapan skrin berikut:E-mel Baru yang Mengandungi Sel Excel Terpilih

Fail PST Sama Rentan dengan Fail Excel

Seperti yang kita ketahui, fail Excel dan dokumen Word mudah rosak. Sebenarnya, perkara yang sama berlaku untuk fail PST, yang mengandungi semua item dalam peti mel Outlook anda. Jadi, adalah tugas yang sukar untuk mengamankan data PST anda. Salah satu langkah yang paling berkesan adalah membuat sandaran fail secara berkala. Tambahan pula, untuk menyediakan penyelamatan segera, lebih baik anda menyediakan alat yang berpengalaman, seperti DataNumen Outlook Repair, yang mampu pulihkan Outlook data tanpa berpeluh.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk baiki mdf dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com

Kongsi Sekarang:

Ruangan komen telah ditutup.