Санал өгөх статистикийг Outlook имэйлээс Excel-ийн ажлын хуудсанд хэрхэн хурдан экспортлох вэ

Outlook шийдлүүд Есдүгээр сарын 29, 2025

Хэрэв та санал өгөх товчлууртай имэйл илгээсэн бол хүлээн авагчид танд хариултаа илгээсний дараа санал өгөх статистикийг тоолж, Excel ажлын хуудас руу экспортлохыг хүсч магадгүй юм. Тиймээс энэ бичлэгт бид үүнийг хэрхэн хурдан хийхийг танд заах болно.

Outlook нь маш хүчирхэг тул "Санал өгөх" функцийг санал болгодог. Миний өмнөх нийтлэл “Санал өгөхдөө MS Outlook-ийг чадварлаг ашиглах"Үүнийг хэрхэн үр дүнтэй ашиглахыг зааж өгсөн. Түүнчлэн, ихэнх тохиолдолд санал өгсний дараа та статистикийг хэвлэх гэх мэт зарим шалтгаанаар санал хураалтын статистикийг Excel ажлын хуудас руу экспортлох боломжтой. Гэхдээ Outlook үүнийг анхдагчаар дэмждэггүй. Тиймээс доор бид үүнийг хэрхэн үйсэн мэт хийхийг танд заах болно.

Санал хураалтын статистикийг Excel-ийн ажлын хуудсанд имэйлээр экспортлох

Хамгийн эхэнд Outlook програмаа ажиллуулна уу.
Дараа нь та Outlook-ийн үндсэн цонхонд "Alt + F11" товчлуурыг дарах хэрэгтэй.
Дараа нь "Microsoft Visual Basic for Applications" цонхонд та "Microsoft Excel Object Library"-г идэвхжүүлэх хэрэгтэй. "Tools" > "Reference" дээр дарна уу. Дараа нь гарч ирэх харилцах цонхонд "Microsoft Excel Object Library"-н өмнөх чагтыг тэмдэглээд эцэст нь "OK" товчийг дарна уу.
Үүний дараа та шинэ модулийг оруулах эсвэл ашиглагдаагүй модулийг нээх боломжтой.
Дараа нь дараахь VBA кодыг хуулж аваад энэ модуль дээр буулгана уу.

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Үүний дараа тав тухтай хандахын тулд та Quick Access Toolbar дээр шинэ макро нэмж оруулсан нь дээр.
Эцэст нь та хичээгээд үзээрэй.

Нэгдүгээрт, санал өгөх товчлууруудыг агуулсан эх имэйлийг сонгоно уу.
Дараа нь Quick Access Toolbar дээрх макро товчийг дарна уу.
Энэ макро ажиллаж дууссаны дараа та урьдчилан тодорхойлсон локал хавтас руу орж үзэх боломжтой бөгөөд үүнд шинэ Excel ажлын дэвтэр гарч ирэх болно.
Энэ Excel-ийн ажлын номыг нээнэ үү. Одоо та санал хураалтын статистикийг доорх зургаар харуулах болно.

Outlook алдааг хэн ч сайтар арилгаж чадахгүй

Хэдийгээр Outlook нь янз бүрийн чадвартай байдаг боловч Outlook-ийн алдаанаас зайлсхийхэд туслах ийм боломж байхгүй. Бүх төрлийн хүчин зүйлүүд нь Outlook-ийн алдааг үүсгэж болзошгүй юм. Жишээлбэл, хэрэв та Outlook-оос ихэвчлэн буруу гарч байвал та зовох болно PST авлига. Ийм тохиолдолд та өөрийн PST файлыг аврахын тулд зарим хүчирхэг хэрэгслийг ашиглахаас өөр аргагүй болно DataNumen Outlook Repair. Энэ нь нөхөн сэргээх өндөр хурдтай тул маш их худлаа олсон.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. авлигач MDF програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com