Хэрхэн олон Outlook имэйлийг VBA-аар нэг үгийн баримт бичигт багцаар экспортлох вэ

Хэрэв та олон Outlook имэйлийг нэг үгтэй баримт бичиг болгон экспортлохыг хүсвэл энэ нийтлэлд үзүүлсэн VBA кодыг ашиглаж болно. Энэ нь танд энэ ажлыг хэдхэн секундын дотор гүйцэтгэхэд тусална.

Би өмнөх нийтлэлдээ Outlook имэйлийг Word баримт руу хэрхэн хөрвүүлэх талаар танилцуулсан.Outlook имэйлийг Word баримт болгон хөрвүүлэх 2 үр дүнтэй арга”. Гэсэн хэдий ч, тэр хуудсанд дурдсан 2 арга хоёулааost Хэрэв та олон имэйлийг нэг Word баримт бичигт багцлан экспортлохыг хүсч байгаа тохиолдолд арчаагүй болно. Тиймээс, энд бид танд өөр аргыг заах болно. Одоо дэлгэрэнгүй уншихын тулд уншина уу.

Олон Outlook имэйлийг нэг үгийн баримт бичигт багцаар экспортлох

1. Start нь, Outlook програмаа ажиллуулаарай.
2. Дараа нь Outlook-ийн үндсэн цонхонд орсны дараа та "Alt + F11" товчийг дарах хэрэгтэй.
3. Дараа нь та хоосон модулийг нээх ёстой Outlook VBA засварлагч руу нэвтрэх боломжтой болно.
4. Дараа нь нээгдсэн модулийн цонхонд доорх VBA кодыг хуулна уу.

Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Үүний дараа та энэ шинэ VBA төслийг Quick Access Toolbar эсвэл туузанд нэмэх нь дээр.
6. Эцсийн эцэст та оролдоод үзэх боломжтой.

• Эхний ээлжинд олон Outlook имэйлийг сонгоно уу.
• Дараа нь олоод шинээр нэмэгдсэн макро товчийг дарна уу.
• "Бүрэн" гэж асуусны дараа та шинэ Word баримтыг хайж олохын тулд урьдчилан тодорхойлсон дотоод хавтас руу орж болно.
• Сонгосон бүх имэйл экспортлогдсоныг харах боломжтой энэ баримт бичгийг нээнэ үү.

Хүчирхэг сэргээх хэрэгслийг ойролцоо байлга

Олон тооны функцээс үл хамааран Outlook нь алдаанаас хамгаалах боломжгүй хэвээр байна. Хэрэв та алдаагаа дангаар нь үлдээж дассан бол Outlook гацах нь гарцаагүй. Энэ үед хүчирхэг, үр дүнтэй сэргээх хэрэгсэлд дахин хандах нь чухал юм DataNumen Outlook Repair. Энэ талаар сайн мэддэг PST засах. Үүнийг ашигласнаар та хэтийн төлөвийн өгөгдөл алдагдах талаар санаа зовох шаардлагагүй болно.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. гэмтсэн mdf програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com