Үгсийн баримтаас хэсэг гаргах 2 хурдан арга

Энэ нийтлэлд бид Word баримтаас өөр нэг юмуу хэд хэдэн хэсгүүдийг задлах хурдан бөгөөд хялбар 2 аргыг санал болгох болно.

Нэг баримтаас нөгөө баримт руу агуулгыг задлах нь ихэвчлэн тохиолддог. Өмнөх нийтлэлдээ бид баримтаас хуудас хэрхэн гаргаж авах талаар ярилцсан. Дэлгэрэнгүй мэдээллийг та энэ нийтлэлээс авч болно: Үгсийн баримт бичгээс тусдаа хуудсыг задлах 2 хурдан арга

Өнөөдөр бид танд хэрхэн хэсэгчлэн задлахыг харуулах болно.    

Арга 1: Одоогийн хэсгийг шинэ баримт бичигт задлах

1. Юуны өмнө курсорыг зорилтот хэсэгт байрлуулна уу.
2. Дараа нь "Alt + F11" товчийг дарж Word дээр VBA засварлагчийг ажиллуулна уу.
3. Дараа нь зүүн баганад "Хэвийн" дээр дарна уу.
4. Мөн цэсний мөрөнд "Оруулах" дээр дарна уу.
5. Дараа нь доош унах цэснээс "Модуль" -ыг сонгоно уу.
6. Шинэ модулийг нээхийн тулд давхар товшиж, дараах кодыг оруулна уу:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. Дараа нь цэсийн мөрөнд "Run" дээр дарна уу эсвэл "F5" дээр дарна уу.
8. Дараа нь "Үзэх" цонх гарч ирнэ. Шинэ баримт бичгийг хадгалах газраа сонгоод "OK" дээр дарна уу.
9. "Файлын нэр" талбарт шинэ файлын нэрийг оруулаад "OK" дээр дарна уу.

Одоо та энэ хэсгийг шинэ баримт бичигт задалсан байна.

Арга 2: Баримт бичгийн хэсэг бүрийг шинээр задлах

Энэ арга нь баримт бичгийн бүх хэсгийг багцлан боловсруулахад тусална. Мэдээжийн хэрэг, бидэнд макро хэрэгтэй болно.

1. Эхлээд зорилтот баримт бичгийг нээнэ үү.
2. Дараа нь макро суулгах, ажиллуулахын тулд 1-р аргын алхмуудыг дагана уу.
3. Зөвхөн энэ удаад тэр макрог түүгээр солино:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. Гэсэн хэдий ч "Browse" цонхноос хадгалах замыг сонгоод "OK" дээр дарна уу.

Цочромтгой үгийн алдааг засах

Word програмыг ашиглах явцад алдаа гарах нь элбэг байдаг. Энэ нь ядаргаатай байж магадгүй, бид үүнд цаг гаргах хэрэгтэй үгийг сэргээх аль болох түргэн. Учир нь бид үүнийг хойшлуулах тусам өгөгдлийн алдагдлыг улам хүндрүүлнэ. Тиймээс засварын хэрэгслийг урьдчилан авахыг зөвлөж байна.

Зохиогчийн танилцуулга:

Вера Чен бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. гэмтсэн xls болон pdf програм хангамжийн бүтээгдэхүүнийг засах. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com