Үгсийн баримт бичгээс тусдаа хуудсыг задлах 2 хурдан арга

Өнөөдрийн бичлэгт бид Word баримтаас хуудсуудыг тусад нь гаргаж авах 2 хурдан аргыг тантай хуваалцахыг хүсч байна.

Заримдаа Word баримт бичигт хуудас бүр нь хүснэгт гэх мэт бие даасан агуулгатай байж болно. Магадгүй та өөр өөр хүснэгтийг өөр хүмүүст илгээх шаардлагатай болж магадгүй юм. Дараа нь та хуудас бүр болох хүснэгт бүрийг тусад нь файл болгон хадгалах хэрэгтэй болно.

Бидний толгойд орж буй анхны санаа бол сонгодог хуулбарлах оо байх ёстой. Гэсэн хэдий ч сонгон шалгаруулалт нь заримдаа ядаргаатай байдаг, яагаад гэвэл чирэх, сонгох нь ямар ч сонголтгүйгээр хялбархан төгсдөг. Энэ шалтгааны улмаас бид танд макро ашиглан 2 хурдан аргыг зөвлөж байна.

Арга 1: Одоогийн хуудсыг гаргаж шинэ баримт болгон хадгалах

1. Юуны өмнө, хулганы заагчийг задлахыг хүссэн хуудас дээрээ байрлуул.
2. VBA засварлагчийг дуудахын тулд "Developer" табыг дараад "Visual Basic" дээр дарна уу. Хэрэв "Хөгжүүлэгч" идэвхжээгүй бол оронд нь "Alt + F11" товчийг дарна уу.
3. Хоёрдугаарт, дарж “Normal” төсөл рүү орно уу.
4. Дараа нь "Insert" таб дээр дарж "Module" -г сонгоно уу.
5. Шинэ модуль дээр давхар товшоод засварлах хэсгийг нээнэ үү.
6. Дараа нь дараах кодыг наа.

Sub SaveCurrentPageAsANewDoc()
  Dim objNewDoc As Document
  Dim objDoc As Document
  Dim strFileName As String
  Dim strFolder As String
 
  '  Initialization
  Set objDoc = ActiveDocument
 
  strFolder = InputBox("Enter folder path here: ")
  strFileName = InputBox("Enter file name here: ")
 
  '  Copy current page.
  objDoc.Bookmarks("\Page").Range.Select
  Selection.Copy
 
  '  Open a new document to paste the selection.
  Set objNewDoc = Documents.Add
  Selection.Paste
 
  objNewDoc.SaveAs FileName:=strFolder & "\" & strFileName & ".docx"
  objNewDoc.Close
End Sub

7. Эцэст нь "Ажиллуулах" товчийг дарна уу.

Одоо 2 оролтын хайрцаг байх болно. Эхний оролтын хайрцагт шинэ баримт бичгийг хадгалах газраа оруулна уу. Хоёрдугаарт шинэ баримт бичгийн нэрийг оруулна уу.

Арга 2: Хуудас бүрийг задалж, шинэ баримт болгон хадгалах

Дараахь макро нь баримт бичгийн хуудас бүрийг задлах боломжийг танд олгоно.

1. Нэгдүгээрт, "Ctrl + Home" товчийг дарж баримт бичгийнхээ эхэнд очно уу.
2. Дараа нь макро суулгаж ажиллуулахын тулд 1-р аргын ижил алхмуудыг дагана уу.
3. Энэ удаа макроыг дараахь байдлаар орлуулаарай.

Sub SaveEachPageAsADoc()
  Dim objNewDoc As Document
  Dim objDoc As Document
  Dim nPageNumber As Integer
  Dim strFolder As String
  Dim objFileName As Range
 
  '  Initialization
  Set objDoc = ActiveDocument
 
  strFolder = InputBox("Enter folder path here: ")
 
  '  Copy each page in the document to paste it into a new one.
  For nPageNumber = 1 To ActiveDocument.ComputeStatistics(wdStatisticPages)
    Application.Browser.Target = wdBrowsePage
    ActiveDocument.Bookmarks("\page").Range.Select
    Selection.Copy
 
    Set objNewDoc = Documents.Add
    Selection.Paste
 
    '  Save new doc with the name of "Page" & nPageNumber and get the first 20 characters of the new doc as part of the file name.
    Set objFileName = objNewDoc.Range(Start:=0, End:=20)
    objNewDoc.SaveAs FileName:=strFolder & "\" & "Page " & nPageNumber & " " & objFileName & ".docx"
    objNewDoc.Close
    Application.Browser.Next
  Next nPageNumber
End Sub

Үгстэй холбоотой асуудлуудыг шийдвэрлэх

Word-д янз бүрийн асуудлууд байсаар байх болно. Гол нь тэдгээрийг зөв засахыг сурах явдал юм. Мэдээж хамгийн зөвлөдөг арга бол нарийн төвөгтэй арга юм. Үг сэргээх хэрэгсэл. Хэтэрхий оройтохоос өмнө өгөгдлөө сэргээхийн тулд минут бүрийг ашиглах хэрэгтэй.

Зохиогчийн танилцуулга:

Вера Чен бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. ялзарсан xlsx болон pdf програм хангамжийн бүтээгдэхүүнийг засах. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com