Kā ātri eksportēt visus Outlook e-pasta attēlu pielikumus uz Excel darblapu

Ja vēlaties ātri eksportēt visus Outlook e-pasta attēla pielikumus uz Excel darblapu, varat skatīt šo rakstu. Šeit mēs parādīsim efektīvāku veidu nekā manuāla eksportēšana.

Kad saņemat e-pastu, kas satur ahost attēlu pielikumus, ja vēlaties tos izmantot atskaites veidošanai programmā Excel, jums ir jātiecas pēc iespējas, kas šos attēlus varētu eksportēt Excel darblapā pa partijām. Tagad mēs jūs iepazīstināsim ar šādu pieeju.

Eksportējiet visus e-pasta attēlu pielikumus uz Excel darblapu

1. Vispirms piekļūstiet savai Outlook lietojumprogrammai parastajā veidā.
2. Pēc tam Outlook logā nospiediet taustiņu īsinājumtaustiņus “Alt + F11”, kas parādīs logu “Microsoft Visual Basic for Applications”.
3. Šajā ekrānā ir jāatver modulis, kas netiek lietots, vai uzreiz jāievieto jauns.
4. Tālāk jums vajadzētu iekopēt tālāk esošo VBA koda daļu šajā modulī.

Sub ExportAllImageAttachmentsToExcelWorksheet()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim strImage As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim objFile As Object
    Dim objFiles As Object
    Dim nRow As Integer
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
 
       'Save the image attachments to a temporary folder
       strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.Attachments
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          objAttachment.SaveAsFile strTempFolder & objAttachment.filename
              End Select
           End If
       Next
 
       'Create a new Excel workbook
        Set objExcelApp = CreateObject("Excel.Application")
        Set objExcelWorkbook = objExcelApp.Workbooks.Add
        Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
        objExcelApp.Visible = True
        objExcelWorkbook.Activate
 
        'Get the images in the temporary folder
        Set objFiles = objFileSystem.GetFolder(strTempFolder).Files
 
        'Insert the images into this new Excel worksheet
        For Each objFile In objFiles
            strImage = strTempFolder & Trim(objFile.Name)
            nRow = nRow + 1
            With objExcelWorksheet
                 .Range("A" & nRow).value = objFile.Name
                 'Change the height and width as per your needs
                 .Range("B" & nRow).ColumnWidth = 10
                 .Range("B" & nRow).RowHeight = 80
                 .Range("B" & nRow).Activate
                 With .Pictures.insert(strImage)
                      With .ShapeRange
                           .LockAspectRatio = msoTrue
                           .Width = 50
                           .Height = 70
                      End With
                 End With
                 .Columns("A").AutoFit
                 .Activate
            End With
       Next
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. Pēc tam varat iziet no makro.
6. Pēc tam dodieties uz “Fails” > “Opcijas” > “Ātrās piekļuves rīkjosla”, lai pievienotu šo makro ātrās piekļuves rīkjoslai.
7. Visbeidzot, varat izmēģināt šo makro tieši tagad.

• Pirmkārt, atlasiet vai atveriet avota e-pastu.
• Pēc tam ātrās piekļuves rīkjoslā noklikšķiniet uz pogas makro.
• Kad makro būs pabeigts, jūs saņemsit Excel darblapu, kas parādīta kā šis ekrānuzņēmums:

Aizsargājiet Outlook failu no sabojāšanas

Ir zināms, ka programma Outlook ir pakļauta korupcijai. Tāpēc mums vajadzētu saprast, kā aizsargāt Outlook veidlapu korupciju. Vispirms, lai bloķētu vīrusu uzbrukumus, ir jāinstalē pretvīrusu programmatūra un nekad nav jālejupielādē nezināms pielikums. Turklāt labāk ir iegūt kādu spēcīgu remonta rīku, piemēram, DataNumen Outlook Repair. Tā var piedāvāt most efektīvs līdzeklis, ja Outlook korupcija.

Autora ievads:

Šērlija Džana ir datu atkopšanas eksperte DataNumen, Inc., kas ir pasaules līderis datu atkopšanas tehnoloģiju, tostarp sql atgūšana un perspektīvas remonta programmatūras produktus. Lai iegūtu vairāk informācijas, apmeklējiet vietni www.datanumen. Ar