Kaip greitai rasti vieno sakinio pastraipas savo Word dokumente

Šiame įraše norime parodyti jums greitą būdą, kaip rasti visas vieno sakinio pastraipas „Word“ dokumente naudojant VBA.

Kartais kai kuriems dokumentams gali būti taikomi labai specifiniai jų formatavimo ir struktūrų reikalavimai. Pavyzdžiui, jums gali būti neleidžiama turėti pastraipų tik su vienu sakiniu. Šias pastraipas nesunku atpažinti, tačiau tai užtrunka, ypač tai ilgas dokumentas.

Šiandien mes pasiūlysime jums greitą būdą nurodyti visas vieno sakinio pastraipas jūsų dokumente.

Raskite visas vieno sakinio pastraipas viename dokumente

1. Pirma, „Word“ skaičiuoja tašką kaip sakinį. Taigi, jei yra tokių žodžių kaip „p. arba „ponia“, „Word“ laiko tai sakiniu. Norėdami pašalinti tokį išsiblaškymą, turite pakeisti žodį „ponas“. su "ponu". Ir kai baigsite rasti vieno sakinio pastraipą, galėsite jas pakeisti atgal. Norėdami pakeisti žodžius, galite naudoti šią nuorodą: Kaip rasti ir pakeisti kelis elementus „Word“ dokumente
2. Antra, paspauskite „Alt + F11“, kad paleistumėte VBA redaktorių.
3. Tada spustelėkite „Įprastas projektas“.
4. Meniu juostoje spustelėkite skirtuką „Įterpti“ ir išskleidžiamajame meniu pasirinkite „Modulis“.
5. Tada dukart spustelėkite modulį, kad jį atidarytumėte.
6. Įklijuokite šiuos kodus modulyje:

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. Paskutinis, bet ne mažiau svarbus dalykas, spustelėkite mygtuką „Vykdyti“ arba paspauskite „F5“.

Jūs gausite tokį pranešimą, kuriame bus pranešta, kad darbas atliktas.

Rasti visas vieno sakinio pastraipas keliuose dokumentuose

1. Pirmiausia turite sudėti visus tikslinius dokumentus į aplanką.
2. Tada įdiekite ir paleiskite toliau pateiktą makrokomandą:

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. Atsidariusiame lange „Naršyti“ pasirinkite aplanką, kuriame saugote dokumentus, ir spustelėkite „Gerai“.

Tada makrokomandos paryškins visas vieno sakinio pastraipas ir paliks dokumentus atvirus. Jei dokumente nėra vieno sakinio pastraipos, jis bus uždarytas. Be to, yra pranešimų laukelis, kuriame nurodomas vieno sakinio pastraipų skaičius kiekviename dokumente.

Susitvarkyti su duomenų praradimo incidentu

Vartotojo klaidos ir staigus elektros energijos tiekimo nutraukimas gali sukelti „Word“ mirtį. Nors sugriuvęs Wordas gali ne tik paveikti kasdienį darbą, bet ir sukelti doc žalaTai tikrai ne pati erzinanti duomenų katastrofos dalis. Geriau gauti taisymo įrankį, kad duomenys būtų nedelsiant atkurti.

Autoriaus įvadas:

Vera Chen yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant susigrąžinti Excel bei pdf programinės įrangos gaminių taisymas. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com