Kaip greitai eksportuoti visus „Outlook“ el. pašto vaizdo priedus į „Excel“ darbalapį

Jei norite greitai eksportuoti visus „Outlook“ el. laiško vaizdo priedus į „Excel“ darbalapį, galite peržiūrėti šį straipsnį. Čia parodysime efektyvesnį būdą nei eksportavimas rankiniu būdu.

Kai gaunate el. laišką su daugybe paveikslėlių priedų, jei norite juos panaudoti ataskaitai „Excel“ programoje kurti, jums reikia būdo, kaip eksportuoti šiuos paveikslėlius į „Excel“ darbalapį partijomis. Toliau pristatysime tokį metodą.

Eksportuokite visus el. laiško vaizdo priedus į „Excel“ darbalapį

1. Pirmiausia įprastu būdu pasiekite „Outlook“ programą.
2. Tada „Outlook“ lange paspauskite „Alt + F11“ sparčiuosius klavišus, kurie atvers „Microsoft Visual Basic for Applications“ langą.
3. Šiame ekrane turite atidaryti nenaudojamą modulį arba iš karto įdėti naują.
4. Tada turėtumėte nukopijuoti toliau pateiktą VBA kodo dalį į šį modulį.

Sub ExportAllImageAttachmentsToExcelWorksheet()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim strImage As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim objFile As Object
    Dim objFiles As Object
    Dim nRow As Integer
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
 
       'Save the image attachments to a temporary folder
       strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.Attachments
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          objAttachment.SaveAsFile strTempFolder & objAttachment.filename
              End Select
           End If
       Next
 
       'Create a new Excel workbook
        Set objExcelApp = CreateObject("Excel.Application")
        Set objExcelWorkbook = objExcelApp.Workbooks.Add
        Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
        objExcelApp.Visible = True
        objExcelWorkbook.Activate
 
        'Get the images in the temporary folder
        Set objFiles = objFileSystem.GetFolder(strTempFolder).Files
 
        'Insert the images into this new Excel worksheet
        For Each objFile In objFiles
            strImage = strTempFolder & Trim(objFile.Name)
            nRow = nRow + 1
            With objExcelWorksheet
                 .Range("A" & nRow).value = objFile.Name
                 'Change the height and width as per your needs
                 .Range("B" & nRow).ColumnWidth = 10
                 .Range("B" & nRow).RowHeight = 80
                 .Range("B" & nRow).Activate
                 With .Pictures.insert(strImage)
                      With .ShapeRange
                           .LockAspectRatio = msoTrue
                           .Width = 50
                           .Height = 70
                      End With
                 End With
                 .Columns("A").AutoFit
                 .Activate
            End With
       Next
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. Po to galite išeiti iš makrokomandos.
6. Tada eikite į „Failas“ > „Parinktys“ > „Greitos prieigos įrankių juosta“, kad pridėtumėte šią makrokomandą prie greitosios prieigos įrankių juostos.
7. Galiausiai galite išbandyti šią makrokomandą dabar.

• Pirmiausia pasirinkite arba atidarykite šaltinio el. laišką.
• Tada greitosios prieigos įrankių juostoje spustelėkite makrokomandos mygtuką.
• Kai makrokomanda bus baigta, gausite „Excel“ darbalapį, parodytą kaip ši ekrano kopija:

Apsaugokite „Outlook“ failą nuo sugadinimo

Yra žinoma, kad „Outlook“ yra linkusi į korupciją. Todėl turėtume suprasti, kaip apsaugoti Outlook formos korupciją. Pirmiausia, norint blokuoti virusų atakas, būtina įdiegti antivirusinę programinę įrangą ir niekada neatsisiųsti nežinomo priedo. Be to, geriau įsigykite galingą remonto įrankį, pvz DataNumen Outlook RepairTai gali pasiūlyti veiksmingiausią priemonę tuo atveju, jei Outlook korupcija.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant sql atkūrimas ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com