Kaip greitai nukopijuoti aplanko struktūrą iš vieno Outlook PST failo į kitą naudojant VBA

Jei norite kopijuoti aplanko struktūrą iš vieno „Outlook“ PST failo į kitą, galite naudoti šiame straipsnyje aprašytą metodą, kuris išmokys jus naudoti VBA, kad jį gautumėte vienu kartu.

Galbūt, norėdami geriau tvarkyti el. laiškus, pagrindiniame „Outlook“ faile sukūrėte kelis pasirinktinius aplankus. Taigi kurdami naują Outlook PST failą, galbūt norėsite taikyti tą pačią aplanko struktūrą. Tiesą sakant, mano ankstesniame straipsnyje - "2 veiksmai, kaip išsaugoti dabartinę aplankų hierarchiją naujame „Outlook“ faile“, galite išmokti tradicinio metodo, naudojant „Archyvavimo“ funkciją. Nepaisant to, iš tikrųjų tai vis dar yra šiek tiek nuobodu. Palyginti su juo, naudojant VBA kodus jį gauti bus daug greičiau. Todėl toliau papasakosime išsamius veiksmus ir kodus.

Nukopijuokite aplanko struktūrą iš vieno Outlook PST failo į kitą

1. Pačioje pradžioje paleiskite „Outlook“ programą.
2. Tada „Outlook“ lange paspauskite klavišų kombinaciją „Alt + F11“.
3. Tada pateksite į Outlook VBA redaktoriaus langą.
4. Tada nukopijuokite ir įklijuokite šiuos VBA kodus į naują modulį.

Public objNewPSTFolder As Outlook.Folder
 
Sub CopyFolderStructure()
    Dim objFolders As Outlook.Folders
    Dim objFolder As Outlook.Folder
 
    'Get the folders of the source Outlook PST file
    Set objFolders = Outlook.Application.Session.Folders("Personal").Folders
 
    'Create the new pst file in your desired local folder and name
    Outlook.Application.Session.AddStore "E:\New PST File.pst"
    Set objNewPSTFolder = Session.Folders.GetLast()
 
    For Each objFolder In objFolders
        CreateFolder objFolder
    Next
 
    MsgBox "Completed!", vbOKOnly + vbInformation, "Copy Folder Structure"
End Sub
 
Sub CreateFolder(objFolder As Outlook.Folder)
    Dim objSubFolder As Outlook.Folder
 
    'Only copy the mail folder
    If (objFolder.DefaultItemType = olMailItem) Then
       'New Outlook PST file auto includes the "Deleted Items" folder, so skip it
       'Skip the useless mail folders - "Conversation Action Settings" and "Quick Step Settings"
       If (objFolder.Name <> "Deleted Items") And (objFolder.Name <> "Conversation Action Settings") And (objFolder.Name <> "Quick Step Settings") Then
 
          'Create the new folder
          objNewPSTFolder.Folders.Add objFolder.Name
          Set objNewPSTFolder = objNewPSTFolder.Folders.Item(objFolder.Name)
 
          For Each objSubFolder In objFolder.Folders
              CreateFolder objSubFolder
          Next
 
          Set objNewPSTFolder = objNewPSTFolder.parent
       End If
    End If

End Sub

5. Po to pakeiskite makrokomandos saugos lygį į žemą.
6. Vėliau grįžkite į VBA redaktoriaus langą ir paspauskite „F5“ klavišą, kad paleistumėte makrokomandą.
7. Galiausiai, kai makrokomanda baigs veikti, gausite pranešimą, raginantį „Baigta!“.
8. Šiuo metu galite pereiti į pašto naršymo sritį. Pamatysite naują „Outlook“ duomenų failą, kuris yra toje pačioje aplanko struktūroje kaip ir šaltinio PST failas, kaip ir toliau pateiktame paveikslėlyje:

Susitvarkykite su slegiančiomis PST problemomis

Kadangi „Outlook PST“ yra klaidų, daugelis iš jūsų turėjo kada nors susidurti su įvairiomis „Outlook“ problemomis. Susidūrę su jais, pirmiausia galite išbandyti „Outlook“ gautųjų taisymo įrankį. Jei nepavyks, galite pritaikyti galingesnį trečiosios šalies įrankį, pvz DataNumen Outlook Repair, kuri gali pataisyti Outlook PST klaidos kaip vėjas.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant SQL Server nustatyti ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com