Kaip nustatyti skirtingą numatytąjį priminimo laiką skirtingų tipų pažymėtiems elementams jūsų „Outlook“

Pagal numatytuosius nustatymus „Outlook“ automatiškai naudos numatytąjį užduočių priminimo laiką visų rūšių pažymėtiems elementams. Tačiau, jei norite naudoti skirtingą priminimo laiką pažymėtoms prekėms pagal elemento tipą, galite remtis šiame straipsnyje pateiktu metodu.

„Outlook“ leidžia nustatyti numatytąjį priminimo laiką visiems pažymėtiems elementams, neatsižvelgiant į elemento tipą. Galite eiti į meniu „Failas“ ir spustelėti „Parinktys“. Tada „Outlook“ parinkčių lange galite matyti parinktį „Numatytasis priminimo laikas“ skirtuke „Užduotys“, kaip parodyta toliau esančioje ekrano kopijoje.

Nepaisant to, dauguma vartotojų tikisi naudoti skirtingą priminimo laiką skirtingų tipų pažymėtiems elementams, pavyzdžiui, „9:00“ pažymėtiems el. laiškams ir „17:30“ pažymėtiems kontaktams. Dabar toliau mes sutelksime dėmesį į šį pavyzdį, kad pristatytume metodą.

Nustatykite skirtingą numatytąjį priminimo laiką skirtingų tipų pažymėtiems elementams

1. Norėdami pradėti, paleiskite „Outlook“ programą.
2. Tada pasiekite „Outlook VBA“ redaktorių, nurodydami „Kaip paleisti VBA kodą „Outlook“.".
3. Kitame lange „Microsoft Visual Basic for Applications“ nukopijuokite šį kodą į „ThisOutlookSession“ projektą.

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Po to paleiskite „Outlook“ iš naujo, kad suaktyvintumėte šią makrokomandą.
5. Nuo šiol kiekvieną kartą, kai pažymėsite el. laišką, priminimo laikas bus nustatytas į „10:00“ žymėjimo terminą.
6. Kai pažymėsite kontaktą, priminimo laikas bus nustatytas į „17:30“ žymėjimo terminą.

Lanksčiai spręskite „Outlook“ problemas

„Outlook“ programoje galite susidurti su įvairiausiomis problemomis. Todėl turite iš anksto išmokti tam tikrų priemonių, kaip jas spręsti. Pavyzdžiui, jei jūsų „Outlook“ dažnai paleidžiama iš naujo, turite pataisyti „Office“ arba išjungti trečiųjų šalių priedus ir pan. Arba, jei jūsų „Outlook PST“ programa buvo pažeista, pirmiausia galite išbandyti pašto dėžutės taisymo įrankis. Kai nepavyksta, galite toliau naudoti galingą išorinį įrankį, pvz., DataNumen Outlook Repair.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant mdf atkūrimas ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com