Kaip paketu pašalinti priedus iš pasenusių kalendoriaus elementų programoje „Outlook“.

Jei norite pašalinti pasenusių susitikimų ir susitikimų priedus programoje „Outlook“, galite perskaityti šį straipsnį. Čia supažindinsime, kaip tai įgyvendinti vienu ypu.

Norint sumažinti „Outlook“ failo dydį, labai patartina išvalyti senus elementus. Tai gali būti padaryta naudojant integruotą „AutoArchive“ funkciją, kuri gali automatiškai reguliariai ištrinti senus elementus. Tačiau kai kurie vartotojai tiesiog nori ištrinti senų elementų priedus nepaveikdami pačių elementų. Toliau išmokysime masiškai pašalinti senų kalendoriaus elementų priedus.

Paketinis priedų pašalinimas iš pasenusių kalendoriaus elementų

1. Norėdami pradėti, pasiekite „Outlook VBA“ rengyklę paspausdami „Alt + F11“.
2. Tada lange „Microsoft Visual Basic for Applications“ nukopijuokite VBA kodą į modulį.

Sub BatchDeleteAttachmentsOfOldCalendarItems()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Change to your own Outlook file
    Set objOutlookFile = Outlook.Application.Session.Folders("John Smith")
 
    For Each objFolder In objOutlookFile.Folders
        If objFolder.DefaultItemType = olAppointmentItem Then
           Call LoopCalendars(objFolder)
        End If
    Next
End Sub

Sub LoopCalendars(ByVal objCalendar As Outlook.Folder)
    Dim i, n As Long
    Dim objCalendarItem As Outlook.AppointmentItem
    Dim nDateDiff As Integer
    Dim objAttachments As Outlook.Attachments
    Dim objSubCalendar As Outlook.Folder
 
    For i = objCalendar.Items.Count To 1 Step -1
        Set objCalendarItem = objCalendar.Items(i)
 
        'Remove attachments from items that are more than 2 months old
        'Change the datediff as per your needs
        nDateDiff = DateDiff("m", objCalendarItem.End, Now) '=> "m" refers to month; "d" for day; "y" for year
        If nDateDiff > 2 Then
           Set objAttachments = objCalendarItem.Attachments
           If objAttachments.Count > 0 Then
              For n = objAttachments.Count To 1 Step -1
                  objAttachments(n).Delete
              Next
           End If
           objCalendarItem.Save
        End If
    Next

    'Process all subfolders recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call LoopCalendars(objSubCalendar)
       Next
    End If
End Sub

3. Po to spustelėkite makrokomandą „BatchDeleteAttachmentsOfOldCalendarItems“.
4. Galiausiai paspauskite „F5“ klavišą, kad paleistumėte šią makrokomandą.
5. Baigę makrokomandą galite patikrinti visus savo „Outlook“ kalendorius.
6. „Outlook“ turi ištrinti visus kalendoriaus elementų priedus, kurie yra senesni nei 2 mėnesiai.

Susitvarkyti su sugadintais Outlook failais

Ar kada nors susidūrėte su „Outlook“ korupcija? Kaip dažniausiai jį išmetate? Dažniausiai pirmiausia išbandykite gautųjų taisymo įrankį – scanpst. Tačiau rimto PST pažeidimo atveju integruotoji programa negali jums padėti. Todėl siūloma netoliese laikyti labiau patyrusį ir nuostabesnį trečiosios šalies įrankį, pvz DataNumen Outlook Repair.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant sql remontas ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com