2 būdai, kaip grupiniu būdu ištrinti visus kontaktus be el. pašto adreso programoje „Outlook“.

Jei pastebėsite, kad kai kurie kontaktai jūsų „Outlook“ programoje neturi el. pašto adreso, galite apdoroti kiekvieną kontaktų aplanką, kad ištrintumėte visus tokius kontaktus. Šiame įraše su jumis bus pasidalinta dviem būdais.

Galbūt „Outlook“ turite daug kontaktų, o kai kurie iš jų neturi el. pašto adreso. Jei manote, kad jie nebenaudingi, turite tikėtis ištrinti visus kontaktus be el. pašto adreso. Standartiniu būdu galite naudoti „Momentinę paiešką“, kad juos surastumėte ir pašalintumėte rankiniu būdu, kaip nurodyta toliau pateiktame 1 metodu. Tačiau tai yra šiek tiek nuobodu. Todėl 2 metodu mes išmokysime jus kito efektyvesnio būdo.

1 būdas: rankiniu būdu ištrinkite radę kontaktus be el. pašto adreso

1. Norėdami pradėti, paspauskite „Ctrl“ + 3“ klavišus, kad pasiektumėte „Kontaktų“ sritį.
2. Tada spustelėkite paieškos laukelį.
3. Tada atsirandančioje juostelėje „Paieška“ spustelėkite „Visi kontaktiniai elementai“.
4. Tada spustelėkite „Turi adresą“ > „Turi el. pašto adresą“.
5. Po to į paieškos laukelį bus įtrauktas kriterijus „NE el. pašto adresai:=[]“. Turite pašalinti „NE“.
6. Vėliau bus pateikti visi kontaktai be el. pašto adresų.
7. Dabar turėtumėte pasirinkti kontaktus paieškos rezultatuose rankiniu būdu, nes jūsų kontaktų grupės taip pat turi būti sąraše.
8. Galiausiai paspauskite mygtuką „Del“, kad ištrintumėte visus pasirinktus kontaktus.

2 būdas: ištrinkite visus kontaktus be el. pašto adreso su VBA

1. Iš pradžių bakstelėkite „Alt + F11“, kad paleistumėte VBA redaktorių programoje „Outlook“.
2. Naujame ekrane nukopijuokite šį VBA kodą į modulį.

Sub BatchDeleteAllContactsWithoutEmailAddress()
    Dim objStore As Outlook.Store
    Dim lTotalCount As Long
 
    lTotalCount = 0
    'Process all stores in your Outlook
    For Each objStore In Application.Session.Stores
       Call ProcessContactFolders(objStore.GetRootFolder.Folders, lTotalCount)
    Next
 
    MsgBox lTotalCount & " contacts are deleted!", vbInformation + vbOKOnly, "Delete Contacts"
End Sub

Sub ProcessContactFolders(ByVal objFolders As Outlook.Folders, lCount As Long)
    Dim objFolder As Outlook.Folder
    Dim i As Long
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder

    For Each objFolder In objFolders
        If (objFolder.DefaultItemType = olContactItem) And (objFolder.Name <> "Skype Contacts") Then
           For i = objFolder.Items.Count To 1 Step -1
               If objFolder.Items(i).Class = olContact Then
                  Set objContact = objFolder.Items(i)
                  'Delete the contact w/o email address
                  If (objContact.Email1Address = "") And (objContact.Email2Address = "") And (objContact.Email3Address = "") Then
                     objContact.Delete
                     lCount = lCount + 1
                  End If
               End If
           Next
 
           'Process subfolders recursively
           If objFolder.Folders.Count > 0 Then
              Call ProcessContactFolders(objFolder.Folders, lCount)
           End If
       End If
    Next
End Sub

3. Vėliau spustelėkite paprogramę „BatchDeleteAllContactsWithoutEmailAddress“.
4. Galiausiai paspauskite „F5“, kad suaktyvintumėte šią makrokomandą.
5. Kai jis bus baigtas, gausite pranešimą apie rezultatus, kaip parodyta paveikslėlyje žemiau.
6. Visi kontaktai be el. pašto adreso buvo perkelti į aplanką „Ištrinti elementai“.

Būkite atokiai nuo visų galimų pavojų

„Outlook“ gali sugesti dėl įvairių veiksnių, tokių kaip virusai, vartotojo klaidos, programinės įrangos gedimai ir aparatinės įrangos gedimai. Turite nenorėti patirti "Outlook" žalos, todėl turite vengti visų šių galimų pavojų. Pavyzdžiui, kompiuteryje turite įdiegti galingą antivirusinę programinę įrangą. Be to, turite reguliariai kurti atsargines „Outlook“ duomenų kopijas. Paskutinis, bet ne mažiau svarbus dalykas – geriau paruoškite tvirtą ir patikimą remonto įrankį, pvz DataNumen Outlook Repair. Tai gali pataisyti jūsų sugadintas PST failą lengvai.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant SQL Server korupcija ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com