Kaip paketu eksportuoti kelis Outlook el. laiškus į vieną Word dokumentą per VBA

„Outlook“ sprendimai Rugsėjis 29, 2025
Bendrinti dabar:

Jei norite paketu eksportuoti kelis Outlook el. laiškus į vieną Word dokumentą, galite naudoti šiame straipsnyje parodytą VBA kodą. Tai gali padėti jums atlikti šią užduotį per kelias sekundes.

Aš kada nors pristačiau, kaip konvertuoti "Outlook" el. laišką į "Word" dokumentą savo ankstesniame straipsnyje - "2 veiksmingi būdai konvertuoti „Outlook“ el. laišką į „Word“ dokumentą“. Tačiau abi 2 priemonės, minimos tame post bus bejėgis tuo atveju, kai norėsite eksportuoti daug el. laiškų į vieną Word dokumentą. Taigi, čia mes išmokysime jus kito būdo. Dabar skaitykite toliau, kad suprastumėte išsamiau.

Paketas eksportuokite kelis Outlook el. laiškus į vieną Word dokumentą naudodami VBA

Pakuotės eksportavimas kelis Outlook el. laiškus į vieną Word dokumentą

  1. Į start su, paleiskite „Outlook“ programą.
  2. Tada, įėjus į pagrindinį „Outlook“ langą, reikia paspausti „Alt + F11“ klavišus.
  3. Tada gausite prieigą prie „Outlook VBA“ rengyklės, kurioje turėtumėte atidaryti tuščią modulį.
  4. Tada nukopijuokite žemiau esantį VBA kodą į atidarytą modulio langą.
Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

VBA kodas – paketinis kelių Outlook el. laiškų eksportavimas į vieną Word dokumentą

  1. Po to geriau pridėti šį naują VBA projektą prie greitosios prieigos įrankių juostos arba juostos.
  2. Galų gale galite pabandyti.
  • Pirmiausia pasirinkite kelis „Outlook“ el.
  • Tada suraskite ir spustelėkite naujai pridėtą makrokomandos mygtuką.
  • Kai būsite paraginti „Užbaigti“, galite naršyti į iš anksto nustatytą vietinį aplanką ir rasti naują „Word“ dokumentą.
  • Atidarykite šį dokumentą, kuriame matote, kad visi pasirinkti el. laiškai buvo eksportuoti.

Netoliese laikykite galingą atkūrimo įrankį

Nepaisant daugelio funkcijų, „Outlook“ vis tiek negali būti apsaugota nuo klaidų. Jei esate įpratę palikti klaidas ramybėje, kai jų daugėja, „Outlook“ strigtis tikrai įvyks. Tuo metu būtina pakartotinai naudoti galingą ir veiksmingą atkūrimo įrankį, pvz DataNumen Outlook Repair. Tai puikiai išmano PST taisymas. Tol, kol su juo, jums nereikės nerimauti dėl Outlook duomenų praradimo.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant sugadintas mdf ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com

Bendrinti dabar:

Komentarai yra uždaryti.