3 greiti būdai, kaip ištrinti tuščias eilutes ir stulpelius savo žodžių lentelėje

Šiame įraše paaiškinsime 3 greitus būdus, kaip ištrinti tuščias eilutes ir stulpelius „Word“ lentelėje.

Lentelės yra būtinos dokumente, ypač turint įvairių tipų duomenis. Kartais ilga lentelė gali viršyti puslapį ir apimti kelis. Taigi, kai lentelė tampa ilga ir sudėtinga, galite imtis priemonių, kad ją supaprastintumėte. Pavyzdžiui, galite ištrinti nereikalingas tuščias eilutes ir stulpelius.

Toliau pateikiami 3 būdai, kuriuos galite naudoti.

1 būdas: rankiniu būdu ištrinkite tuščias eilutes ir stulpelius

1. Pirmiausia pasirinkite tuščią eilutę arba stulpelį.
2. Tada dešiniuoju pelės mygtuku spustelėkite, kad atidarytumėte kontekstinį meniu. Meniu atitinkamai pasirinkite „Ištrinti eilutes“ arba „Ištrinti stulpelius“.

Deja, šiuo būdu negalite pasirinkti kelių ne iš eilės eilučių ar stulpelių ir jų ištrinti kartu. Dėl šio reikalavimo galite peržiūrėti ankstesnį mūsų straipsnį: 5 greiti būdai, kaip paketiniu būdu ištrinti kelias eilutes ar stulpelius savo Word lentelėje

2 būdas: paketiniu būdu ištrinkite visas tuščias lentelės eilutes ir stulpelius

1 metodas turi savo apribojimus. Taigi mes pasiūlysime jums būdą, kaip paketais pašalinti lentelės eilutes ir stulpelius naudojant VBA kodus.

1. Norėdami pradėti, įkelkite žymeklį į tikslinę lentelę.
2. Antra, suaktyvinkite VBA redaktorių paspausdami „Alt + F11“.
3. Redagavimo priemonėje pirmiausia spustelėkite „Įprastas“ projektas.
4. Tada meniu juostoje spustelėkite skirtuką „Įterpti“.
5. Išskleidžiamajame meniu pasirinkite „Modulis“.
6. Dukart spustelėkite modulį, kad jį atidarytumėte ir įklijuokite šiuos kodus:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Galiausiai meniu juostoje spustelėkite mygtuką „Vykdyti“ arba paspauskite „F5“.

Per kelias sekundes iš tos lentelės bus pašalintos visos tuščios eilutės ir stulpeliai.

3 būdas: ištrinkite visas tuščias eilutes ir stulpelius visose dokumento lentelėse

1. Pirmiausia pakartokite 2 metodo veiksmus, kad įdiegtumėte ir paleistumėte makrokomandą.
2. Tik šį kartą pakeiskite šią makrokomandą tokia:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Atkurti sugadintą dokumentą

Šiais laikais yra daugiau nei vienas būdas atkurti prarastus duomenis. Pavyzdžiui, atsarginių kopijų kūrimas visada išlieka svarbiausiu prioritetu. Jei tai netenkina jūsų poreikio atgauti naujausią informaciją, galite pabandyti... doc remontas įrankis.

Autoriaus įvadas:

Vera Chen yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant xlsx remontas bei pdf programinės įrangos gaminių taisymas. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com