2 būdai, kaip greitai sujungti kelis Word dokumentus į vieną per VBA

Šiame straipsnyje mes džiaugiamės galėdami pasidalinti su jumis 2 būdais, kaip greitai sujungti kelis Word dokumentus į vieną per VBA.

„Word“ yra numatytoji integruota funkcija, padedanti vartotojui sujungti arba sujungti kelis dokumentus į vieną. Išsami informacija paaiškinta šiame straipsnyje: Kaip sujungti ir sujungti kelis Word dokumentus į vieną

Taikant šį metodą, jūs turite padaryti keletą paspaudimų ir kito dokumento turinys visada pasirodo iškart po ankstesnio dokumento. Todėl norime jums pasiūlyti greitesnius būdus tai padaryti.

1 būdas: sujunkite pasirinktus dokumentus į vieną

1. Visų pirma, sukurkite naują tuščią dokumentą.
2. Suaktyvinkite VBA redaktorių Word paspausdami „Alt + F11“.
3. Tada spustelėkite „Normalus“.
4. Tada spustelėkite „Įterpti“.
5. Ir pasirinkite „Modulis“.
6. Dukart spustelėkite naują modulį, kad atidarytumėte redagavimo erdvę.
7. Įklijuokite ten šią makrokomandą:

Sub MergeMultiDocsIntoOne()
  Dim dlgFile As FileDialog
  Dim nTotalFiles As Integer
  Dim nEachSelectedFile As Integer

  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    .AllowMultiSelect = True
    If .Show <> -1 Then
      Exit Sub
    Else
      nTotalFiles = .SelectedItems.Count
    End If
  End With
 
  For nEachSelectedFile = 1 To nTotalFiles
    Selection.InsertFile dlgFile.SelectedItems.Item(nEachSelectedFile)
    If nEachSelectedFile < nTotalFiles Then
      Selection.InsertBreak Type:=wdPageBreak
    Else
      If nEachSelectedFile = nTotalFiles Then
        Exit Sub
      End If
    End If
  Next nEachSelectedFile
End Sub

8. Tada spustelėkite „Vykdyti“ arba paspauskite „F5“.
9. Dabar lange „Naršyti“ pasirinkite kelis failus paspausdami „Ctrl“ ir spustelėkite „Gerai“.
10. Tada visas pasirinktų failų turinys bus sujungtas į naują dokumentą, o kiekvieno dokumento tekstai prasidės naujame puslapyje.

Pastaba:

Kaip minėjome, ši makrokomanda perkelia kiekvieno dokumento tekstus į naują puslapį. Bet jei reikia, kad jos būtų viena po kitos, makrokomandoje galite pakeisti kai kurias kodo eilutes. Tiesiog suraskite eilutę „If nEachSelectedFile < nTotalFiles Tada“, ištrinkite ją ir kitas šešias eilutes.

2 būdas: sujunkite visus aplanke esančius dokumentus į vieną

Jei turite failų, kuriuos norite sujungti, aplanką, ši makrokomanda veiks puikiai.

1. Norėdami pradėti, įdiekite ir paleiskite makrokomandą, kaip aprašyta 1 metode.
2. Tada pakeiskite makrokomandą šia:

Sub MergeFilesInAFolderIntoOneDoc()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder As String, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      .InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
End Sub

3. Paleiskite makrokomandą spustelėdami „Vykdyti“.
4. Tada pamatysite atidarytą langą „Naršyti“. Pasirinkite aplanką, kuriame saugosite visus dokumentus. Ir spustelėkite „Gerai“.

Panašiai kiekvieno dokumento tekstai prasideda naujame puslapyje. Kad jie suliptų vienas po kito, suraskite ir ištrinkite kodo eilutę „.InsertBreak Type:=wdPageBreak“.

Tinkamai apsaugokite savo Word dokumentą

Vienas geriausių būdų apsaugoti „Word“ dokumentus – reguliariai kurti atsargines jų kopijas. Turėdami atsargines kopijas, niekada nereikės bijoti duomenų praradimo. Be to, taip pat patartina gauti įrankį taisyti docx jei kuris nors iš jų bus pažeistas.

Autoriaus įvadas:

Vera Chen yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant sugadintas Excel bei pdf programinės įrangos gaminių taisymas. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com