2 greiti būdai, kaip rasti arba ištrinti sakinius, kuriuose yra konkretus tekstas jūsų žodyje

Šiame straipsnyje mes jums pasiūlysime 2 greitus būdus, kaip rasti arba ištrinti sakinius, kuriuose yra konkretus tekstas jūsų Worde.

Visiems žinoma, kad „Word“ programoje galime naudoti funkciją „Rasti ir pakeisti“, kad lengvai rastume visus konkrečių žodžių atvejus. Tada neturėsime problemų juos paryškindami, pakeisdami ar pašalindami. Kaip matote, tikslas yra žodis arba frazė. Tačiau šiandien džiaugiamės galėdami papasakoti apie makrokomandą, kaip rasti arba ištrinti sakinius, kuriuose yra tam tikras tekstas.

1 būdas: raskite arba ištrinkite sakinius, kuriuose yra konkretaus teksto

1. Norėdami pradėti, paspauskite „Alt + F11“, kad paleistumėte VBA redaktorių „Word“.
2. Tada sukurkite naują modulį spustelėdami „Įprastas“.
3. Tada spustelėkite „Įterpti“ ir pasirinkite „Modulis“, kad gautumėte naują.
4. Ir atidarykite modulį dukart spustelėdami.
5. Dabar įklijuokite šiuos kodus:

Sub DeleteSentencesContainingSpecificWords()
  Dim strTexts As String
  Dim strButtonValue As String
 
  strTexts = InputBox("Enter texts to be found here: ")
 
  With Selection
    .HomeKey Unit:=wdStory
 
    '  Find the entered texts.
    With Selection.Find
      .ClearFormatting
      .Text = strTexts
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute
    End With
 
    Do While .Find.Found = True
      '  Expand the selection to the entire sentence.
      Selection.Expand Unit:=wdSentence
      strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
      If strButtonValue = vbYes Then
        Selection.Delete
      End If
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
End Sub

6. Toliau spustelėkite „Vykdyti“.
7. Bus įvesties laukelis, kuriame bus prašoma įvesti tekstą. Tiesiog įveskite bendrą tekstą, kuris yra visuose sakiniuose. Spustelėkite „Gerai“.
8. Tada pamatysite sakinį, kuriame yra pasirinktas tekstas su pranešimo langeliu. Spustelėkite „Taip“, kad ištrintumėte sakinį, ir „Ne“, jei norite jį palikti.
9. Po patvirtinimo pasirenkamas kitas sakinys su nurodytu tekstu. Taip pat yra patvirtinimo laukelis. Makrokomanda nukreipia jus per visą dokumentą, ieškodama tikslinių sakinių ir kaskart prašydama patvirtinimo.

2 būdas: raskite arba ištrinkite sakinius, kuriuose yra bet koks sąraše esantis tekstas

Naudodami 1 metodo makrokomandą vienu metu galite ieškoti tik vieno žodžio ar frazės. Žinoma, galite pakartotinai paleisti makrokomandą ir ieškoti kelių žodžių ar frazių pavyzdžių. Norėdami patenkinti kelių paieškų poreikį, pateiksime kitą makrokomandą.

1. Pirmiausia visus tikslinius tekstus įkelkite į naują dokumentą. Įsitikinkite, kad kiekvienas teksto fragmentas užima vieną pastraipą be tarpų gale. Uždarykite ir išsaugokite dokumentą.
2. Tada įdiekite ir paleiskite makrokomandą tiksliai atlikdami 1 metodo veiksmus.
3. Tada pakeiskite makrokomandą šia:

Sub DeleteSentencesContainingSpecificWordsOnAList()
  Dim objListDoc As Document, objTargetDoc As Document
  Dim objParaRange As Range
  Dim objParagraph As Paragraph
  Dim strFileName As String, strButtonValue As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    If .Show = -1 Then
      strFileName = .SelectedItems(1)
    Else
      MsgBox "No file is selected! Please select the target file."
      Exit Sub
    End If
  End With
  Set objTargetDoc = ActiveDocument
  Set objListDoc = Documents.Open(strFileName)
  objTargetDoc.Activate
 
  For Each objParagraph In objListDoc.Paragraphs
    Set objParaRange = objParagraph.Range
    objParaRange.End = objParaRange.End - 1
 
    With Selection
      .HomeKey Unit:=wdStory
 
      '  Find target words.
      With Selection.Find
        .ClearFormatting
        .Text = objParaRange
        .MatchWholeWord = True
        .MatchCase = False
        .Execute
      End With
 
      '  Expand the selection to the entire sentence.
      Do While .Find.Found
        Selection.Expand Unit:=wdSentence
        strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
        If strButtonValue = vbYes Then
          Selection.Delete
        End If
        .Collapse wdCollapseEnd
        .Find.Execute
      Loop
    End With
  Next objParagraph
End Sub

4. Dabar atsidarys langas „Naršyti“. Pasirinkite ką tik išsaugotą dokumentą ir spustelėkite „Atidaryti“.
5. Ši procedūra yra tokia pati, kaip ir 1 metodu.

Korumpuotų dokumentų sprendimo būdas

Vertingų duomenų praradimas yra visiškai niokojantis. Dėl to jūsų verslas gali net likti ant kortos. Kad išvengtumėte tokio nusivylimo, turite sugriebti a Žodžių taisymas įrankį kuo greičiau. Toks įrankis padės laimėti kovą su dokumentų korupcija.

Autoriaus įvadas:

Vera Chen yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant pataisyti Excel bei pdf programinės įrangos gaminių taisymas. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com