Outlook 연락처에서 특정 도메인의 모든 전자 메일 주소를 일괄 제거하는 방법

Outlook 솔루션 2025 년 9 월 29 일

특정 도메인을 사용하는 모든 이메일 주소를 연락처에서 삭제하고 싶을 때가 있습니다. 하지만 일일이 하나씩 삭제하는 것은 번거로울 수 있습니다. 이 글에서는 훨씬 효율적인 방법을 알려드리겠습니다.

예를 들어, 회사 이름이 변경됩니다. 한편 회사 도메인도 변경됩니다. 그러나 Outlook에서는 이메일 주소가 이전 도메인에있는이 회사에 많은 연락처를 저장했습니다. 물론 이러한 이메일 주소는 더 이상 유효하지 않습니다. 따라서 이러한 상황에서 이러한 이메일 주소를 한 번에 제거하려면 다음 방법을 사용할 수 있습니다.

연락처에서 특정 도메인의 모든 이메일 주소 일괄 제거

우선 단축키 "Alt + F11"을 눌러 Outlook VBA 편집기에 액세스하세요.
그런 다음 새 창에서 다음 VBA 코드를 빈 모듈에 배치합니다.

Dim strDomain As String

Sub BatchRemoveAllEmailAddressesInSpecificDomain()
    Dim objStore As Store
    Dim objFolder As Folder
    Dim lTotalCount As Long
 
    'Input the specific domain
    strDomain = InputBox("Enter the specific domain:", , "@false.com")
 
    If Len(strDomain) <> 0 Then
       lTotalCount = 0
       'Process all Contact folders in your Outlook
       For Each objStore In Application.Session.Stores
           For Each objFolder In objStore.GetRootFolder.Folders
               If objFolder.DefaultItemType = olContactItem Then
                  Call ProcessContactFolders(objFolder, lTotalCount)
               End If
           Next
       Next
 
       'Prompt you
       MsgBox lTotalCount & " email addresses in " & strDomain & " are removed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessContactFolders(ByVal objCurrentFolder As Folder, ByRef lCount As Long)
    Dim objContacts As Items
    Dim i As Long
    Dim objContact As ContactItem
 
    Set objContacts = objCurrentFolder.Items
 
    For i = objContacts.Count To 1 Step -1
        If TypeName(objContacts(i)) = "ContactItem" Then
           Set objContact = objContacts(i)
 
           'Check 3 email addresses of each contact
           If InStr(objContact.Email1Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email1Address = ""
              objContact.Email1DisplayName = ""
           ElseIf InStr(objContact.Email2Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email2Address = ""
              objContact.Email2DisplayName = ""
           ElseIf InStr(objContact.Email3Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email3Address = ""
              objContact.Email3DisplayName = ""
           End If
 
           objContact.Save
        End If
     Next
 
     If objCurrentFolder.Folders.Count > 0 Then
        For Each objSubfolder In objCurrentFolder.Folders
            Call ProcessContactFolders(objSubfolder, lCount)
        Next
     End If
End Sub

그 후 커서를“BatchRemoveAllEmailAddressesInSpecificDomain”서브 루틴에 놓습니다.
마지막으로 "F5"키 버튼을 클릭하여이 매크로를 트리거합니다.
그런 다음 팝업 대화 상자에 특정 도메인을 입력합니다.
“확인”을 클릭하면 매크로가 실행됩니다.
완료되면 결과에 대한 메시지가 표시됩니다.
이제 연락처를 확인할 수 있습니다. 특정 도메인의 모든 이메일 주소가 사라졌어 야합니다.

Outlook 파일 보존

Outlook을 둘러싼 위험이 점점 더 커지면서 귀중한 Outlook 데이터를 보호하는 것이 점점 더 어려워지고 있습니다. 예를 들어, 정기적 인 데이터 백업을 유지해야 할뿐만 아니라 작업을 조심해야합니다. 알 수없는 발신자가 보낸 이메일을 쉽게 신뢰하는 것은 현명하지 않습니다. 그렇지 않으면 바이러스가있는 경우 Outlook 파일이 감염됩니다. 그 때, 당신은 시도해야 Outlook 수리 다음과 같은 놀라운 수정 도구를 통해 DataNumen Outlook Repair.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. 복구 Sql Server 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM