한 폴더의 모든 하위 폴더에서 Outlook의 다른 폴더로 전자 메일을 일괄 이동하는 방법

Outlook 솔루션 2025 년 9 월 29 일

여러 하위 폴더가있는 폴더가있을 수 있습니다. 이러한 하위 폴더의 모든 이메일을 특정 폴더로 빠르게 이동하는 등 이메일을 재구성하려면이 문서에서 공유하는 방법을 사용할 수 있습니다.

때때로 이메일을 재 분류하려는 등의 이유로 한 폴더의 모든 하위 폴더에서 다른 폴더로 이메일을 일괄 이동해야 할 수 있으므로 이러한 하위 폴더는 더 이상 유용하지 않습니다. 이 경우 이러한 하위 폴더를 하나씩 처리하는 것은 매우 번거로운 작업입니다. 따라서 여기서 우리는 다른 방법을 소개합니다.

한 폴더의 모든 하위 폴더에서 다른 폴더로 이메일 일괄 이동

처음에는 start Outlook 프로그램.
그런 다음 기본 Outlook 화면에서 "Alt + F11"키 버튼을 눌러 VBA 편집기로 이동합니다.
다음으로 새로운“Microsoft Visual Basic for Applications”창에서 사용하지 않는 모듈을 열어야합니다.
그런 다음 다음 VBA 코드를 복사하여이 모듈에 붙여 넣습니다.

Dim objTargetFolder As Outlook.folder

Sub BatchMoveEmailsFromSubfoldersToAnotherFolder()
    Dim objSourceFolder As Outlook.folder
    Dim objFolder As Outlook.folder
  
    'Get the source folder whose subfolders to be processed
    Set objSourceFolder = Application.Session.PickFolder
 
    If Not (objSourceFolder Is Nothing) And objSourceFolder.DefaultItemType = olMailItem Then
       If objSourceFolder.folders.count > 0 Then
          'Select a target folder
          Set objTargetFolder = Application.Session.PickFolder
          If Not (objTargetFolder Is Nothing) Then
             For Each objFolder In objSourceFolder.folders
                 Call ProcessFolders(objFolder)
             Next
             MsgBox "Move Completed!", vbExclamation
          End If
       Else
          MsgBox "No subfolders!", vbExclamation
       End If
    End If
End Sub

Sub ProcessFolders(ByVal objFolder As Outlook.folder)
    Dim i As Long
    Dim objSubfolder As Outlook.folder
 
    For i = objFolder.Items.count To 1 Step -1
        'Move emails to the target folder
        If objFolder.Items(i).Class = olMail Then
           objFolder.Items(i).Move objTargetFolder
        End If
    Next
 
    'Process subfolders recursively
    If objFolder.folders.count > 0 Then
       For Each objSubfolder In objFolder.folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

그 후에이 매크로를 실행할 수 있습니다.

먼저이 매크로 창에서 "F5"키 버튼을 누릅니다.
그런 다음 하위 폴더를 처리 할 소스 폴더를 선택해야합니다.
그런 다음 이메일을 이동할 대상 폴더를 지정해야합니다.
결과적으로이 매크로는tart 일. 완료되면 "완료"라는 메시지가 표시됩니다.
궁극적으로 tar폴더를 가져옵니다. 소스 폴더 아래에있는 하위 폴더의 모든 이메일이 거기에있는 것을 볼 수 있습니다.

손상된 Outlook 데이터 복원

다른 이메일 클라이언트와 같이 다양한 기능을 자랑하지만 Outlook도 여전히 손상에서 벗어날 수 없습니다. 더 많은 데이터가 저장됨에 따라 Outlook은 오류와 손상에 점점 더 취약해질 것입니다. 따라서 다음과 같은 강력한 수리 도구를 편리하게 보관해야합니다. DataNumen Outlook Repair. 특히 Outlook 수정 문제. 따라서 쉽게 손상된 Outlook 파일을 스캔하고 복원 할 수 있습니다.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. mdf 복구 및 전망 수리 소프트웨어 제품. 자세한 내용은 www.datKanumen.com