Word құжатындағы бір сөйлемді абзацтарды қалай тез табуға болады

Бұл жазбада біз сізге Word құжатыңыздағы барлық бір сөйлемнен тұратын абзацтарды VBA арқылы қалай тез табуға болатынын көрсеткіміз келеді.

Қазір және кей кезде кейбір құжаттарда олардың пішімдері мен құрылымдарына өте нақты талаптар қойылуы мүмкін. Мысалы, сізде тек бір сөйлемнен тұратын абзацтардың болуына тыйым салынуы мүмкін. Бұл абзацтарды тану қиын емес, бірақ бұл уақытты қажет етеді, әсіресе бұл ұзақ құжат.

Бүгін біз сізге құжаттағы барлық бір сөйлемді абзацтарды көрсетудің жылдам әдісін ұсынамыз.

Бір құжаттан бір сөйлемнің барлық абзацтарын табыңыз

1. Біріншіден, Word кезеңді сөйлем ретінде санайды. «Мистер» сияқты сөздер болса немесе «ханым», Word оны сөйлем ретінде қарастырады. Мұндай алаңдаушылықты болдырмау үшін «мырзаны» ауыстыру керек. мырзамен ». Бір сөйлемнің абзацын тапқаннан кейін, оларды қайтадан өзгертуге болады. Сөздерді ауыстыру үшін мына сілтемеге жүгіне аласыз: Word құжатындағы бірнеше заттарды қалай табуға және ауыстыруға болады
2. Екіншіден, VBA редакторын іске қосу үшін «Alt + F11» пернелерін басыңыз.
3. Содан кейін «Қалыпты» жобасын басыңыз.
4. Мәзір жолағындағы «Вставка» қойындысын нұқыңыз және оның ашылмалы мәзірінен «Модуль» таңдаңыз.
5. Оны ашу үшін модульді екі рет нұқыңыз.
6. Модульге келесі кодтарды қойыңыз:

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. Ең соңында, бірақ «Іске қосу» батырмасын басыңыз немесе «F5» батырмасын басыңыз.

Сізге жұмыс аяқталғанын айтатын осындай хабарлама терезесі келеді.

Барлық құжаттардан бір сөйлемнен тұратын абзацтарды табыңыз

1. Бастау үшін барлық мақсатты құжаттарды қалтаға салу керек.
2. Содан кейін макросты орнатыңыз және іске қосыңыз:

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. «Шолу» терезесінде құжаттарды сақтайтын қалтаны таңдап, «ОК» батырмасын басыңыз.

Содан кейін макрос барлық сөйлемдердің абзацтарын бөліп, құжаттарды ашық қалдырады. Егер құжатта бір сөйлемнен тұратын абзац болмаса, ол жабық болады. Сонымен қатар, әр құжаттағы бір сөйлемнен тұратын абзацтардың санын көрсететін хабарлама терезесі бар.

Деректерді жоғалту оқиғасымен күресу

Пайдаланушының қателіктері және электр қуатының кенеттен өшуі Word-тың өліміне әкелуі мүмкін. Әдетте, құлаған сөз күнделікті жұмысқа әсер етіп қана қоймай, сонымен қатар әкелуі мүмкін doc зақымдануыБұл деректер апатының ең тітіркендіргіш бөлігі емес. Деректерді дереу қалпына келтіру үшін жөндеу утилитасын алған дұрыс.

Автордың кіріспесі:

Вера Чен - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. excel қалпына келтіру және pdf бағдарламалық жасақтама өнімдерін жөндеу. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com