Дауыс беру статистикасын Outlook электрондық поштасынан Excel жұмыс парағына қалай жылдам экспорттауға болады

Outlook шешімдері Қыркүйек 29, 2025
Қазір бөлісу:

Дауыс беру түймелері бар электрондық поштаны жіберген болсаңыз, алушылар сізге жауаптарын жібергеннен кейін, дауыс беру статистикасын Excel жұмыс парағына санап, экспорттағыңыз келуі мүмкін. Сонымен, осы бost, біз сізге оған қалай тез жетуге болатынын үйретеміз.

Outlook соншалықты күшті, ол тіпті «Дауыс беру» мүмкіндігін ұсынады. Менің алдыңғы мақалам «Дауыс беру үшін MS Outlook бағдарламасын шебер пайдалану» оны қалай тиімді пайдалану керектігін үйретті. Сондай-ақ, мost уақыт өткеннен кейін, дауыс беруден кейін статистиканы басып шығаруды қалау сияқты кейбір себептерге байланысты дауыс беру статистикасын Excel жұмыс парағына экспорттауды жалғастыра аласыз. Бірақ Outlook әдепкі бойынша бұны қолдамайды. Осылайша, келесіде біз мұны тығын сияқты қалай жүзеге асыруға болатынын үйретеміз.

Дауыс беру статистикасын Outlook электрондық поштасынан Excel жұмыс парағына жылдам экспорттаңыз

Электрондық поштадағы дауыс беру статистикасын Excel жұмыс парағына экспорттау

  1. Ең басында Outlook қосымшасын іске қосыңыз.
  2. Содан кейін негізгі Outlook терезесіндегі «Alt + F11» пернелерін басу керек.
  3. Келесі «Қолданбаларға арналған Microsoft Visual Basic» терезесінде «Microsoft Excel Object Lib» қосу керек.rary”. «Құралдар» > «Анықтама» түймесін басыңыз. Содан кейін қалқымалы диалогтық терезеде «Microsoft Excel Object Library» түймесін басып, соңында «OK» түймесін басыңыз.
  4. Осыдан кейін сіз жаңа модульді енгізе аласыз немесе пайдаланылмайтын модульді аша аласыз.
  5. Осы модульге келесі VBA кодтарын көшіріңіз және қойыңыз.
Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

VBA коды - Outlook электрондық поштасынан Excel жұмыс парағына дауыс беру статистикасын экспорттау

  1. Осыдан кейін, ыңғайлы қол жеткізу үшін жылдам қол жеткізу құралдар тақтасына жаңа макросты қосқан дұрыс.
  2. Ақыр соңында, сіз көріңіз.
  • Біріншіден, дауыс беру түймелері бар бастапқы электрондық поштаны таңдаңыз.
  • Содан кейін жылдам қол жеткізу құралдар тақтасындағы макро батырманы басыңыз.
  • Бұл макросты іске қосуды аяқтағаннан кейін, сіз жаңа Excel жұмыс кітабын көретін алдын ала анықталған жергілікті қалтаны шолуға болады.
  • Осы Excel жұмыс кітабын ашыңыз. Енді сіз төмендегі суретте көрсетілген дауыс беру статистикасын көресіз:Экспортталған дауыс беру статистикасы

Ешкім Outlook қателерін мұқият болдырмайды

Outlook бағдарламасы әртүрлі мүмкіндіктермен жабдықталғанымен, Outlook қателерін болдырмауға көмектесетін мұндай мүмкіндік жоқ. Барлық факторлар Outlook қателерін тудыруы мүмкін. Мысалы, Outlook бағдарламасынан жиі дұрыс шықпасаңыз, зардап шегуіңіз мүмкін PST сыбайлас жемқорлық. Мұндай сценарийде сіздің PST файлыңызды құтқару үшін кейбір күшті құралдарды пайдаланудан басқа таңдауыңыз жоқ. DataNumen Outlook Repair. Ол қалпына келтіру жылдамдығының жоғары болуына байланысты көптеген мақтауларға ие болды.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. сыбайлас MDF және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com

Қазір бөлісу:

Пікірлер жабылды.