Әрбір Outlook қалтасындағы элементтердің жалпы санын Excel бағдарламасына қалай жылдам экспорттауға болады

Әрбір Outlook қалтасындағы элементтердің саны туралы есеп алғыңыз келсе, осы мақалада ұсынылған әдісті пайдалана аласыз. Ол санауды жылдам орындайды және нәтижелерді Excel файлына экспорттайды.

Менің алдыңғы мақаламда - «Outlook VBA арқылы қалтадағы және оның барлық ішкі қалталарындағы элементтердің жалпы санын қалай жылдам алуға болады”, қалтадағы элементтердің санын алу үшін VBA көмегімен әдісті үйренуге болады. Дегенмен, осылайша, егер сіз барлық қалталардағы элементтерді санағыңыз келсе, әрбір қалтаны таңдап, макросты бір-бірден іске қосуыңыз керек. Бұл біраз жалықтырады. Сондықтан біз сізге есептеуді Excel файлына экспорттайтын басқа әдісті үйретеміз.

Әрбір Outlook қалтасындағы элементтердің жалпы санын Excel бағдарламасына экспорттаңыз

1. Бастапқыда Outlook бағдарламасын іске қосыңыз.
2. Содан кейін негізгі Outlook терезесінде «Alt + F11» батырмаларын басыңыз.
3. Содан кейін сіз «Қолданбаларға арналған Microsoft Visual Basic» терезесіне кіресіз, онда пайдаланылмаған модульді ашу қажет.
4. Кейіннен келесі модульге VBA кодын көшіріңіз және қойыңыз.

Public strExcelFile As String
Public objExcelApp As Excel.Application
Public objExcelWorkbook As Excel.Workbook
Public objExcelWorksheet As Excel.Worksheet

Sub Export_CountOfItems_InEachFolder_toExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Create a new Excel file
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Count Items"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Items Count (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderItemCount As Long
    Dim nLastRow As Integer
 
    lCurrentFolderItemCount = objCurrentFolder.Items.Count
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nLastRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nLastRow) = lCurrentFolderItemCount
 
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Осыдан кейін Outlook макроқауіпсіздік деңгейін төмен деңгейге өзгерту керек.
6. Содан кейін жаңадан қосылған макросқа оралып, осы макросты іске қосу үшін F5 пернесін басыңыз.
7. Содан кейін бастапқы PST файлын таңдап, «OK» түймесін басыңыз.
8. Макрос аяқталғаннан кейін келесі скриншотқа ұқсайтын жаңа Excel файлын табу үшін алдын ала анықталған жергілікті қалтаға өтуге болады:

Тітіркендіргіш PST қателерін реттеңіз

Outlook бағдарламасын пайдалану кезінде әртүрлі мәселелерге тап болған шығарсыз. Кішкентай мәселелерді шешу үшін сіз жай ғана жүгіне аласыз кіріс жәшігін жөндеу құралы. Дегенмен, егер проблемалар ішкі құрал жасай алмайтындай күрделі болса, сізге күштірек құралды пайдалану керек, мысалы: DataNumen Outlook Repair.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. mdf жөндеу және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com