Барлық ішкі қалталары мен элементтері бар Outlook қалтасын Windows қалтасына қалай жылдам экспорттауға болады

Кейде барлық ішкі қалталары мен элементтері бар Outlook қалтасын Windows қалтасына пакеттік экспорттағыңыз келуі мүмкін. Бұл мақала сізге Outlook VBA қолданатын әдісті үйретеді.

Outlook қалтасын бір қалта құрылымындағы барлық элементтермен жергілікті дискіге экспорттағыңыз келгенде, сақтау және қолмен экспорттауды таңдасаңыз, бұл сізге көп уақытты алады. Сонымен, неге экспорттау құралдары немесе VBA кодтары сияқты басқа құралдарға жүгінбейсіз? Мұнда біз сізге VBA кодының осындай бөлігін ашамыз. Бұл сізге жел сияқты жетуге мүмкіндік береді.

Outlook қалтасындағы барлық ішкі қалталар мен элементтерді Windows қалтасына экспорттау

1. Ең басында Outlook бағдарламаңызды іске қосыңыз.
2. Содан кейін негізгі Outlook терезесінде «Alt + F11» пернелер тіркесімін басыңыз.
3. Содан кейін «Қолданбаларға арналған Microsoft Visual Basic» терезесі пайда болады.
4. Әрі қарай бос модульді ашып, оған келесі VBA кодтарын көшіру керек.

Private objFileSystem As Object
 
Private Sub ExportFolderWithAllItems()
    Dim objFolder As Outlook.Folder
    Dim strPath As String
 
    'Specify the root local folder
    'Change it as per your needs
    strPath = "E:\Outlook\"
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    'Select a Outlook PST file or Outlook folder
    Set objFolder = Outlook.Application.Session.PickFolder
 
    Call ProcessFolders(objFolder, strPath)
 
    MsgBox "Complete", vbExclamation
End Sub
 
Private Sub ProcessFolders(objCurrentFolder As Outlook.Folder, strCurrentPath As String)
    Dim objItem As Object
    Dim strSubject, strFileName, strFilePath As String
    Dim objSubfolder As Outlook.Folder
 
    'Create the local folder based on the Outlook folder
    strCurrentPath = strCurrentPath & objCurrentFolder.Name
    objFileSystem.CreateFolder strCurrentPath
 
    For Each objItem In objCurrentFolder.Items
 
        strSubject = objItem.Subject
 
        'Remove unsupported characters in the subject
        strSubject = Replace(strSubject, "/", " ")
        strSubject = Replace(strSubject, "\", " ")
        strSubject = Replace(strSubject, ":", "")
        strSubject = Replace(strSubject, "?", " ")
        strSubject = Replace(strSubject, Chr(34), " ")

        strFileName = strSubject & ".msg"
 
        i = 0
        Do Until False
           strFilePath = strCurrentPath & "\" & strFileName
           'Check if there exist a file in the same name
           If objFileSystem.FileExists(strFilePath) Then
              'Add a sequence order to the file name
              i = i + 1
              strFileName = strSubject & " (" & i & ").msg"
           Else
              Exit Do
          End If
        Loop
 
        'Save as MSG file
        objItem.SaveAs strFilePath, olMSG
    Next
 
    'Process subfolders recursively
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder, strCurrentPath & "\")
       Next
    End If
End Sub

5. Осыдан кейін Outlook бағдарламасының макрос параметрлерінде макростарға рұқсат беретініне көз жеткізу керек.
6. Ақыр соңында, сіз көріңіз.

• Біріншіден, жаңа макрос терезесіне оралыңыз.
• Содан кейін «ExportFolderWithAllItems» ішкі бағдарламасына басыңыз.
• Осы макросты іске қосу үшін F5 батырмасын басыңыз.
• Осыдан кейін сіз белгілі бір қалтаны таңдауыңыз керек.
• Соңында, «Аяқталды» деген хабарды алған кезде, алдын ала анықталған жергілікті қалтаға кіруге болады. Барлық элементтердің бір қалта құрылымында сақталғанын табасыз.

Outlook бұзылуынан деректердің жоғалуын болдырмаңыз

Мүмкін сіз Outlook бағдарламасының көптеген істен шығуларына тап болған шығарсыз. Көп жағдайда, қайта іске қосқаннан кейін, Outlook қалыпты жұмыс істей алады. Дегенмен, біздің PST файлымыз бүлінуі мүмкін жағдай да бар. Сол кезде сіз PST деректеріңізді қалпына келтіруге тырысасыз, мысалы, тәжірибелі құралға қайталап. DataNumen Outlook Repair. Бұл қабілетті Outlook бағдарламасын түзетіңіз Қателерді жойып, бұзылған PST файлынан деректерді шығармай алыңыз.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. SQL Server жөндеу және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com