Excel жұмыс парағына Outlook электрондық поштасының барлық сурет қосымшаларын қалай жылдам экспорттауға болады

Егер сіз Outlook электрондық поштасының барлық сурет қосымшаларын Excel жұмыс парағына жылдам экспорттағыңыз келсе, осы мақаланы қараңыз. Мұнда біз сізге қолмен экспорттаудан гөрі тиімді жолды көрсетеміз.

Сурет қосымшалары көп электрондық пошта алған кезде, егер сіз оларды Excel бағдарламасында есеп жасау үшін пайдаланғыңыз келсе, бұл суреттерді Excel жұмыс парағына топтап экспорттайтын жолды іздеуіңіз керек. Енді біз сізге осындай тәсілді төменде таныстырамыз.

Электрондық поштаның барлық суреттер қосымшаларын Excel жұмыс парағына экспорттаңыз

1. Бастау үшін әдеттегідей Outlook бағдарламасына кіріңіз.
2. Содан кейін, Outlook терезесінде «Alt + F11» пернелер тіркесімін басыңыз, сонда «Microsoft Visual Basic for Applications» терезесі шығады.
3. Бұл экранда сізге пайдаланылмаған модульді ашу керек немесе жаңасын тікелей енгізу керек.
4. Әрі қарай, сіз төмендегі VBA кодын осы модульге көшіруіңіз керек.

Sub ExportAllImageAttachmentsToExcelWorksheet()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim strImage As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim objFile As Object
    Dim objFiles As Object
    Dim nRow As Integer
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
 
       'Save the image attachments to a temporary folder
       strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.Attachments
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          objAttachment.SaveAsFile strTempFolder & objAttachment.filename
              End Select
           End If
       Next
 
       'Create a new Excel workbook
        Set objExcelApp = CreateObject("Excel.Application")
        Set objExcelWorkbook = objExcelApp.Workbooks.Add
        Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
        objExcelApp.Visible = True
        objExcelWorkbook.Activate
 
        'Get the images in the temporary folder
        Set objFiles = objFileSystem.GetFolder(strTempFolder).Files
 
        'Insert the images into this new Excel worksheet
        For Each objFile In objFiles
            strImage = strTempFolder & Trim(objFile.Name)
            nRow = nRow + 1
            With objExcelWorksheet
                 .Range("A" & nRow).value = objFile.Name
                 'Change the height and width as per your needs
                 .Range("B" & nRow).ColumnWidth = 10
                 .Range("B" & nRow).RowHeight = 80
                 .Range("B" & nRow).Activate
                 With .Pictures.insert(strImage)
                      With .ShapeRange
                           .LockAspectRatio = msoTrue
                           .Width = 50
                           .Height = 70
                      End With
                 End With
                 .Columns("A").AutoFit
                 .Activate
            End With
       Next
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. Осыдан кейін макростан шығуға болады.
6. Осы макросты жылдам қол жетімді құралдар тақтасына қосу үшін «Файл»> «Опциялар»> «Жылдам қатынау тақтасы» тармағына өтіңіз.
7. Сонымен, дәл қазір осы макросты пайдаланып көруге болады.

• Біріншіден, бастапқы электрондық поштаны таңдаңыз немесе ашыңыз.
• Содан кейін жылдам қол жеткізу құралдар тақтасындағы макро батырманы басыңыз.
• Макрос аяқталғаннан кейін сіз келесі скриншот сияқты көрсетілген Excel жұмыс парағын аласыз:

Outlook файлын бүлінуден сақтаңыз

Outlook сыбайлас жемқорлыққа бейім екені белгілі. Сондықтан, Outlook бағдарламасындағы сыбайлас жемқорлықты қалай қорғау керектігін түсінуіміз керек. Біріншіден, вирустық шабуылдарды болдырмау үшін антивирустық бағдарламалық жасақтаманы орнатып, белгісіз тіркемені ешқашан жүктемеу қажет. Сонымен қатар, біз күшті жөндеу құралын алғанымыз жөн DataNumen Outlook RepairОл келесі жағдайда ең тиімді емдеу әдісін ұсына алады. Сыбайлас жемқорлық көрінісі.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. SQL қалпына келтіру және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com