Барлық гипер сілтемелерді бірнеше Outlook электрондық поштасына Excel-ге қалай жылдам экспорттауға болады

Бір немесе бірнеше электрондық поштадағы барлық гиперсілтемелерді алу қажет болған кезде, оларды бір-бірлеп көшіру ақымақтық. Бұл жазба сізге көптеген электрондық пошталардағы барлық гиперсілтемелерді Excel бағдарламасына жылдам экспорттау әдісін үйретеді.

Кейбір жіберілген хаттардағы гипер сілтемелерді тіркеу сияқты кейбір себептер бойынша сіз сілтемелерді алып тастауыңыз керек. Оларды қолмен шығарып алу және көшіру күмән тудырмайды. Сіз VBA-ны пайдалану сияқты әлдеқайда ақылды тәсілді көксеуіңіз керек. Мұнда біз сізге VBA кодының бір бөлігін ұсынамыз, ол көптеген электрондық хаттардағы барлық сілтемелерді оңай басу арқылы Excel-ге экспорттауға қабілетті.

Барлық гипер сілтемелерді бірнеше электрондық пошта арқылы Excel-ге экспорттаңыз

1. Бастау үшін Outlook бағдарламаңызды әдеттегідей іске қосыңыз.
2. Содан кейін, Outlook терезесінде «Alt + F11» батырмаларын басу керек.
3. Сіз бірден Outlook VBA редакторына қол жеткізе аласыз.
4. Содан кейін, «Microsoft Word нысан кітапханасын» және «Microsoft Excel нысан кітапханасын» қосу керек. «Құралдар» > «Сілтемелер» тармағын таңдап, қалқымалы диалогтық терезеде оларды қосыңыз.
5. Әрі қарай сізге төмендегі VBA кодын осы модульге көшіру керек пайдаланылмаған модульді ашу керек.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllHyperlinksInMultipleEmailsToExcel()
    Dim objSelection As Selection
    Dim objMail As MailItem
    Dim objMailDocument As Document
    Dim objHyperlink As Hyperlink
    Dim i As Long
 
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
 
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
       objExcelApp.Visible = True
       objExcelWorkbook.Activate
 
       With objExcelWorksheet
            .Cells(1, 1) = "No."
            .Cells(1, 2) = "Displaying Text"
            .Cells(1, 3) = "Address"
            .Cells(1, 4) = "Source Mail"
      End With
 
      On Error Resume Next
      i = 0
      For Each objMail In objSelection
          objMail.Display
          Set objMailDocument = objMail.GetInspector.WordEditor
          If objMailDocument.Hyperlinks.Count > 0 Then
             For Each objHyperlink In objMailDocument.Hyperlinks
                 If InStr(objHyperlink.Address, "www.") > 0 Then
                    i = i + 1
                    Call ExportToExcel(i, objMail, objHyperlink)
                 End If
             Next
          End If
          objMail.Close olDiscard
      Next
 
      objExcelWorksheet.Columns("A:D").AutoFit
    End If
End Sub

Sub ExportToExcel(n As Long, objCurrentMail As MailItem, objCurrentHyperlink As Hyperlink)
    Dim nLastRow As Integer
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    objExcelWorksheet.Range("A" & nLastRow) = n
    objExcelWorksheet.Range("B" & nLastRow) = objCurrentHyperlink.TextToDisplay
    objExcelWorksheet.Range("C" & nLastRow) = objCurrentHyperlink.Address
    objExcelWorksheet.Range("D" & nLastRow) = objCurrentMail.Subject
End Sub

6. Осыдан кейін сіз ағымдағы VBA редакторы терезесінен шыға аласыз.
7. Жаңадан қосылған макросты жылдам қол жетімді құралдар тақтасына қосу үшін жылдам қол жетімді құралдар тақтасын теңшеу үшін кейінірек «Outlook опцияларына» қол жеткізіңіз.
8. Соңында сіз түсірілім жасай аласыз:

• Алдымен, электрондық пошта тізімінен гипер сілтемелерді алғыңыз келетін электрондық хаттарды таңдаңыз.
• Содан кейін жылдам қол жеткізу құралдар тақтасындағы макро батырманы басыңыз.
• Макросты аяқтағаннан кейін сіз Excel файлын аласыз, мысалы, төмендегі сурет:

Outlook бағдарламасында күтпеген мәселелерді түзету

Outlook мәселелері мезгіл-мезгіл ешқандай нышансыз туындауы мүмкін. Бірақ, шағын қателіктерге келетін болсақ, Outlook қарапайым қайта іске қосу немесе оның көмегімен қалпына келтірілуі мүмкін. кіріс жәшігін жөндеу құралы. Бірақ кейбір күрделі қиындықтарға тап болсаңыз, ішкі құралдар әсер етпейді. Осы сәтте сіздің соңғы курортыңыз неғұрлым беделді және сенімді құрал болып табылады, мысалы DataNumen Outlook Repair.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. бүлінген mdf және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com