A слайдтарын қалай жылдам бекітуге болады PowerPoint Outlook электрондық поштаңызға презентация

Егер сіз a слайдтарын шығарғыңыз келсе PowerPoint презентацияны бөлек жаңа презентацияға қосыңыз және оны Outlook электрондық поштасына қосыңыз, осы мақалада бөліскен әдісті пайдалана аласыз.

Тұтасты бекітудің орнына PowerPoint презентация электронды поштаға, егер сіз презентацияның нақты слайдтарын тіркегіңіз келсе, жалпы, алдымен белгілі слайдтарды жаңа презентацияға көшіруіңіз керек. Бұл тым мазасыз. Сондықтан, мұнда біз сізге оны бір сәтте жүзеге асыра алатын әдісті көрсетеміз.

A слайдтарын бекітіңіз PowerPoint Электрондық поштаға презентация

1. Алдымен, спецификаны ашыңыз PowerPoint презентация.
2. Содан кейін PowerPoint бағдарлама терезесінде VBA редакторына кіру үшін «Alt + F11» пернелерін басыңыз.
3. Әрі қарай, жаңа терезеде «Кірістіру»> «Модуль» батырмаларын басу арқылы жаңа модуль жасаңыз.
4. Кейіннен келесі модульге VBA кодын көшіріңіз және қойыңыз.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. Осыдан кейін сіз ағымдағы терезені жаба аласыз.
6. Кейінірек «Файл»> «Параметрлер»> «Жылдам қатынау құралдар тақтасы» тармағына өтіп, жылдам қол жеткізу тақтасына жаңа макросты қосыңыз.
7. Соңында, сіз осы макросты пайдаланып көре аласыз.

• Бастау үшін, шығарып алғыңыз келетін нақты слайдтарды таңдаңыз.
• Содан кейін жылдам қол жеткізу құралдар тақтасындағы макро батырманы басыңыз.
• Бірден Outlook электрондық поштасы пайда болады, онда а бар PowerPoint бастапқы презентациядан алынған презентация.

Тиімді қалпына келтіру құралын қолданыңыз

Барлығымыз білетіндей, Outlook бағдарламасында кіріктірілген жөндеу утилитасы бар - Сканерлеу. Дегенмен, ол Outlook бағдарламасындағы кішігірім ақауды жеңе алады. Егер сізде кездесетін нәрсе ауыр зиян болса, бұл нәтиже бермейді. Сол кезде сізде тағы бір қуатты және сенімді жөндеу құралына жүгінуден басқа таңдау жоқ DataNumen Outlook Repair. Оның көмегімен сіз бүлінген Outlook файлын сақтай аласыз.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. бүлінген mdf және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com