Windows қалтасындағы соңғы өзгертілген файлды Outlook электрондық поштасына қалай жылдам қосуға болады

Кейде сіз Windows-тың белгілі бір қалтасындағы соңғы өзгертілген файлды тез тауып, Outlook электрондық поштасына қосқыңыз келуі мүмкін. Бұл жағдайда сіз осы мақалада енгізілген әдісті қолдана аласыз.

Кейбір пайдаланушылар Outlook бағдарламасының Windows қалтасындағы соңғы өзгертілген файлды, мысалы, ең соңғы жасалған, өзгертілген немесе сақталған файлды тез тауып, электрондық поштаға қосуын қалайды. Дегенмен, Outlook мұндай тікелей және жергілікті мүмкіндікті ұсынбайды. Сондықтан, төменде біз оны оңай жүзеге асыра алатын VBA кодының бір бөлігін көрсетеміз.

Электрондық поштаға соңғы өзгертілген файлды Windows қалтасына тіркеңіз

1. Ең басында Outlook бағдарламасын іске қосу керек.
2. Негізгі Outlook терезесіне кіргеннен кейін «Alt + F11» батырмаларын басуға болады.
3. Одан кейін сіз Outlook VBA редакторының терезесіне сәттілікпен қол жеткізесіз.
4. Кейіннен сіз қолданылмаған модульді тауып, ашуға тиіссіз.
5. Осы модуль терезесіне келесі VBA кодын көшіріңіз және қойыңыз.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Осыдан кейін сіз ағымдағы VBA редакторының терезесінен шығып, жылдам қол жеткізуге арналған құралдар тақтасына немесе хабарлама терезесіне жаңа макросты қосуға болады.
7. Кейінірек Outlook макроқауіпсіздік деңгейін төмен деңгейге өзгерту керек.
8. Ақыр соңында сіз көріңіз.

• Біріншіден, әдеттегідей жаңа Outlook электрондық поштасын жасаңыз және жасаңыз.
• Содан кейін жылдам қол жеткізу құралдар тақтасындағы макро батырманы басыңыз, төмендегі суреттегідей:
• Әрі қарай сізден Windows терезесінің бастапқы қалтасын таңдап, «OK» батырмасын басу қажет болады.
• Егер таңдалған Windows қалтасында осындай файл болса, сіз келесі скриншот сияқты шақыру аласыз:
• «Иә» басқан кезде, бұл файл бірден тіркеледі.

Outlook мәселелерін мүмкіндігінше тезірек шешіңіз

Кез-келген Outlook мәселелерімен кездескенде, оларды мүмкіндігінше тезірек шешу ұсынылады. Мұндай жағдайда сіз мықты дайындағаныңыз жөн Outlook түзетуі сияқты алдын-ала құрал DataNumen Outlook Repair. Ол PST қателерін түзетуге және Outlook деректеріңізді тиімді сақтауға қабілетті.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. бүлінген mdf және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com