Бірнеше Outlook хабары (.msg) файлдарынан барлық алушыларды қалай жылдам шығарып алуға болады

Outlook шешімдері Қыркүйек 29, 2025

Кейбір пайдаланушылар Outlook электрондық пошталарынан сақталған бірнеше Outlook хабарлары файлдарынан барлық алушыларды жылдам шығарып алғысы келеді. Енді, бұл бost жылдам тәсілмен бөлісу үшін осыны қарастырады.

Алушыларды бір Outlook хабар файлынан шығару үшін оны ашу үшін екі рет шертіп, ашылған Хабар терезесінде алушыларды көшіруге болады. Бірақ, Outlook хабар файлдарының пакетімен жұмыс істеу қажет болса, қолмен орындалатын әдіс жеткілікті тиімді емес. Осылайша, сіз әлдеқайда тиімді жолды іздей аласыз. Міне, біз сізге осындай нәрсені таныстырамыз. Оның мәліметтерін білу үшін оқыңыз.

Бірнеше Outlook хабары (.msg) файлдарынан барлық алушыларды шығарып алыңыз

Үшінtart, сәйкес Outlook VBA редакторына қол жеткізіңіз «Outlook бағдарламасында VBA кодын қалай іске қосуға болады«.
Содан кейін келесі VBA кодын көшіріп, бос модульге қойыңыз.

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

Содан кейін курсорды бірінші ішкі бағдарламаға жылжытыңыз.
Содан кейін «Іске қосу» түймесін басыңыз немесе «F5» пернесін басыңыз.
Содан кейін қалқымалы диалогтық терезеде бастапқы Outlook хабары (.msg) файлдары бар Windows қалтасын таңдаңыз.
Таңдағаннан кейін макросты жалғастыру үшін «OK» түймесін басыңыз.
Макрос аяқталған кезде, келесі скриншотта көрсетілгендей, барлық шығарылған алушылардың электрондық пошта мекенжайлары көрсетілген хабарлама көрсетіледі.

Outlook деректеріңізді қауіптен қорғаңыз

Outlook деректері сыбайлас жемқорлыққа бейім. Демек, Outlook деректерін қорғау өте ауыр міндет. Ол сізге Outlook деректерінің тұрақты сақтық көшірмесін жасауды талап етеді. Сондай-ақ, мүмкін болса, тәжірибелі және кәсіби көзқарасты дайындауға кеңес беріледі PST жөндеу сияқты құрал DataNumen Outlook Repair, осылайша Outlook бағдарламасының бүлінуі жағдайында дереу және уақтылы құтқаруға қол жеткізе аласыз.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. қалпына келтіру Sql Server және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com