Outlook электрондық поштаңызда нақты доменмен барлық гипер сілтемелерді қалай бума етіп ашуға болады

Денесінде көптеген сілтемелері бар Outlook электрондық поштасын көргенде, сіз тек белгілі бір доменмен сілтемелерді жылдам ашқыңыз келуі мүмкін. Мұнда біз осындай гипер сілтемелерді жаппай ашудың әдісін бөлісеміз.

Бір электрондық поштадағы бірнеше сілтемелерге байланысты, сіз олардың барлығын емес, кейбіреулерін тексеруге үміттенесіз. Мысалы, сіз белгілі бір доменмен еренсілтемелерді топтық түрде ғана ашқыңыз келеді. Жалпы, оларды ашу үшін бірінен соң бірін басу керек. Бұл өте мазасыз. Сондықтан, келесілерде біз сізге ыңғайлы тәсілді үйретеміз.

Электрондық пошта арқылы белгілі бір доменмен барлық гипер сілтемелерді пакеттік түрде ашыңыз

1. Бастау үшін Outlook VBA редакторына «Outlook бағдарламасында VBA кодын қалай іске қосуға болады«.
2. Кейіннен, «Қолданбаларға арналған Microsoft Visual Basic» терезесінде «MS Word нысан кітапханасына» сілтемені «VBA бағдарламасында объект кітапханасына сілтемені қалай қосуға болады«.
3. Содан кейін келесі VBA кодын пайдаланылмаған модульге немесе жобаға көшіріңіз.

Sub BatchOpenHyperlinksWithSpecificDomain()
    Dim objMail As MailItem
    Dim objMailDocument As Word.Document
    Dim objHyperlink As Word.Hyperlink
    Dim objDictionary As Object
    Dim i As Integer
    Dim varHyperlinks As Variant
    Dim varHyperlink As Variant
    Dim objInternetExplorer As Object
 
    'Get the source email
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
    Set objMailDocument = objMail.GetInspector.WordEditor
    For Each objHyperlink In objMailDocument.Hyperlinks
        If InStr(1, objHyperlink.Address, "www.datanumen.com") > 0 Then
           'Add Hyperlinks to Dictionary
           If objDictionary.Exists(objHyperlink.Address) = False Then
              objDictionary.Add objHyperlink.Address, 1
           End If
        End If
    Next
 
    'Batch Open Hyperlinks on different tabs in same Internet Explorer window
    Set objInternetExplorer = CreateObject("InternetExplorer.Application")
    varHyperlinks = objDictionary.Keys
    For i = LBound(varHyperlinks) To UBound(varHyperlinks)
        varHyperlink = varHyperlinks(i)
 
        If i = 0 Then
           objInternetExplorer.Visible = True
           objInternetExplorer.navigate varHyperlink
        Else
           objInternetExplorer.navigate varHyperlink, CLng(2048)
        End If
    Next
End Sub

4. Әрі қарай, бұл макросты жылдам қол жетімді құралдар тақтасына немесе таспаға қосыңыз.
5. Соңында, байқап көру үшін келесі әрекеттерді орындаңыз.

• Алдымен Outlook электрондық поштасын таңдаңыз немесе ашыңыз.
• Содан кейін, макро батырманы басыңыз.
• Электрондық поштадағы алдын-ала анықталған доменмен гипер сілтемелер бірден Internet Explorer-де бума ретінде ашылады, бұл келесі суретте көрсетілгендей:

Болжамдық тітіркендіргіштен арылыңыз

Outlook қателіктер мен сыбайлас жемқорлыққа сезімтал болғанымен, сіз барлық тәуекелдерді ескере отырып, олардан оңай құтыла аласыз. Мысалы, сіз жүйелі түрде Outlook үшін деректердің сақтық көшірмесін жасап отыруыңыз керек. Сонымен қатар, сізде вирустар болуы мүмкін күдікті хаттарға назар аударған жөн. Соңғы, бірақ маңызды емес, сіз ан дайындағаныңыз жөн Перспективаны жөндеу сияқты утилита DataNumen Outlook Repair. Ол сізге Outlook-тағы сыбайластық жағдайында көмектесе алады.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. бүлінген SQL Server және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com