Жұмыс уақытыңызға байланысты Outlook бағдарламасын онлайн немесе офлайн режимінде қалай орнатуға болады

Кейбір пайдаланушылар Outlook қолданбасын жұмыс уақытына қарай онлайн және офлайн күй арасында автоматты түрде ауыстыруды қалайды. Сонымен, осы мақалада біз сіздермен жылдам әдісті бөлісеміз.

Шын мәнінде, Outlook бағдарламасын онлайн немесе офлайн режимінде орнату өте оңай. Outlook бағдарламасын офлайн күйге айналдыру үшін жай ғана «Жіберу/қабылдау» қойындысына ауысып, «Офлайн режимінде жұмыс істеу» түймесін басыңыз. Желі күйіне оралу үшін жай ғана осы түймені қайта басыңыз. Дегенмен, кейбір пайдаланушылар Outlook жұмыс уақыты біткен кезде автоматты түрде офлайн күйіне ауысады және жұмыс уақытында желіге оралады деп үміттенеді. Outlook мұндай мүмкіндікті қамтамасыз етпесе де, оған қол жеткізу үшін келесі VBA кодын пайдалана аласыз.

Жұмыс уақытыңызға қарай Outlook онлайн немесе офлайн режимін автоматты түрде орнату

1. Ең басында Outlook қолданбаңызды іске қосыңыз.
2. Содан кейін, Outlook бағдарламасына қол жеткізгеннен кейін, Тапсырмалар қалтасын ашу керек.
3. Әрі қарай күнделікті қайталанатын тапсырма элементін жасау керек.

• Таспадағы «Жаңа тапсырма» түймесін басыңыз.
• Содан кейін тапсырма тақырыбы жолына «Офлайн» сөзін енгізіңіз.
• Содан кейін «Тапсырма» қойындысының астындағы «Қайталану» түймесін басыңыз.
• Қалқымалы диалогтық терезеде «Күнделікті» қайталану үлгісін таңдап, «Аяқтау күні жоқ» параметрін қосыңыз және «OK» түймесін басыңыз.
• Одан кейін «5:00-де» еске салғышты қосу керек.
• Соңында «Сақтау және жабу» түймесін басыңыз.

4. Одан кейін «Онлайн» деп аталатын тағы бір күнделікті қайталанатын тапсырма жасап, төмендегі суретте көрсетілген «Сағат 8:00» еске салғышты қосу керек:
5. Осыдан кейін Outlook негізгі терезесінде «Alt + F11» пернелерін басыңыз.
6. Әрі қарай сіз Outlook VBA редакторына қол жеткізесіз, онда «ThisOutlookSession» жобасын тауып ашу керек.
7. Кейінірек осы жобаға келесі VBA кодын көшіріңіз.

Dim objNameSpace As Outlook.NameSpace

'Set Online/Offline Status on Outlook Startup
Private Sub Application_Startup()
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    'If now is before 8:00 AM or after 5:00 PM on Outlook startup
    If Now() < DateSerial(Year(Now), Month(Now), Day(Now)) + #8:00:00 AM# Or Now() > DateSerial(Year(Now), Month(Now), Day(Now)) + #5:00:00 PM# Then
 
       'If Outlook is online
       If objNameSpace.Offline = False Then
          'set it offline
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
 
       'If now is between 8:00 AM and 5:00 PM
    Else
 
       'If Outlook is offline
       If objNameSpace.Offline = True Then
          'Set it online
          ActiveExplorer().CommandBars.FindControl(, 5613).Execute
       End If
    End If
End Sub

'Change Online/Offline Status at Specific Time
Private Sub Application_Reminder(ByVal Item As Object)
    Dim objOfflineTask As Outlook.TaskItem
    Dim objOnlineTask As Outlook.TaskItem
 
    Set objNameSpace = Application.GetNamespace("MAPI")
 
    If TypeOf Item Is TaskItem Then
       If Item.Subject = "Offline" Then
          Set objOfflineTask = Item
 
          'If Outlook is online when "Offline" task reminder alerts
          If objNameSpace.Offline = False Then
             'Set Outlook offline
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          'Clear the reminder by marking task complete
          objOfflineTask.MarkComplete
 
       ElseIf Item.Subject = "Online" Then
          Set objOnlineTask = Item
 
          'If Outlook is offline when "Online" task reminder alerts
          If objNameSpace.Offline = True Then
             'Set Outlook online
             ActiveExplorer().CommandBars.FindControl(, 5613).Execute
          End If
 
          objOnlineTask.MarkComplete
 
       End If
    End If
End Sub

8. Ақырында, осы макросты іске қосу үшін Outlook бағдарламасын қайта іске қосуға болады.
9. Бұдан былай Outlook бағдарламасы жұмыс уақытында желіде болады және жұмыс уақытынан тыс уақытта офлайн күйге автоматты түрде ауысады.

Outlook бұзылған жағдайда сіздің соңғы құралыңыз

Outlook бағдарламасының көптеген мүмкіндіктері бар болса да, Outlook әлі де қателер мен зақымдардан аулақ бола алмайды. Бірақ үрейленбеңіз. Жеткілікті сақтық шараларын жасасаңыз, Outlook деректерін тиімді қорғай аласыз. Мысалы, PST файлдарының сақтық көшірмесін жүйелі түрде жасау керек, себебі сақтық көшірмелер сізге қайта оралуға мүмкіндік береді сыбайлас PST деректер. Сондай-ақ, қуатты жөндеу құралын сақтау, сияқты DataNumen Outlook Repair, сонымен қатар қажеттілік мәселесі.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. mdf түзету және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com