Сөздік құжатқа бөлімді тез енгізудің 3 әдісі

Бұл мақалада біз сізге Word құжатына бөлім үзілімдерін жылдам енгізудің 3 әдісін көрсетуге назар аударамыз.

Бөлімнің үзілістері құжатты бөлімдерге, тарауларға және т.б. бөлу үшін пайдалы, сонымен қатар бөлім үзілімдерін енгізу әр түрлі беттерге әр түрлі тақырыптар мен төменгі колонтитулдарды орнатудың ажырамас бөлігі болып табылады.

Әдетте, біз параққа өтіп, жүгіргіні тиісті жерде табуымыз керек. Әрі қарай «Бет орналасуы» мен «Үзілістерді» басыңыз. Содан кейін ашылмалы мәзірден бөлімді үзу түрін таңдаңыз. Мұндай іс жүргізу кейде жалықтыруы мүмкін. Сондықтан, біз сізді әдеттегі әдеттен құтқарып, тез және лас шешім қабылдағымыз келеді.

1-әдіс: Белгілі бір бетке бөлім үзілімін енгізу

1. Біріншіден, VBA редакторын шақыру үшін Word бағдарламасындағы «Alt + F11» пернелерін басыңыз.
2. Содан кейін сол жақ бағандағы «Қалыпты» батырмасын басу арқылы жаңа модуль жасаңыз.
3. Содан кейін мәзір жолағындағы «Кірістіру» қойындысын нұқыңыз.
4. «Кірістіру» ашылмалы мәзірінен «Модульді» таңдаңыз.
5. Жаңа модульді ашу үшін оны екі рет басыңыз.
6. Кодирование аймағына келесі макросты қойыңыз:

Sub InsertBreakOnSpecificPage()
  Dim strPageNum As String
  Dim nPageNum As Integer
 
  strPageNum = InputBox("Enter a page number: ")
  nPageNum = Int(strPageNum)
 
  Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=nPageNum
  ActiveDocument.Bookmarks("\page").Range.Select
  Selection.Collapse wdCollapseEnd
  Selection.InsertBreak Type:=wdSectionBreakContinuous
End Sub

7. Енді кодтарды орындау үшін «Іске қосу» батырмасын басыңыз немесе «F5» пернесін басыңыз.
8. Келесіде, сұрау жолағына мақсатты беттің бет нөмірін енгізіңіз. Жалғастыру үшін «Жарайды» түймесін басыңыз.

Әзірге сіз 2-беттің соңына бөлім үзілімін енгіздіңіз.

Ескерту:

Егер сіз бірнеше парақтарды бөлім ретінде бөлімдер үзілістерін қолдана отырып бөлгіңіз келсе, сізге бөлім үзілімін екі рет енгізу керек, бірін алдыңғы бөліктің соңғы парағының соңына және осы жаңа бөлімнің соңғы парағының соңына. .

Мұндай жағдайда бірінші үзілісті енгізу кезінде сіз алдыңғы бөлімнің соңғы парағының бет нөмірі болатын дұрыс санды енгізгеніңізді есте ұстағаныңыз жөн.

2-әдіс: Құжаттың әр парағына бөлімдер үзілімін енгізу

1. Біріншіден, макросты жоғарыда көрсетілген қадамдар бойынша орнатыңыз және іске қосыңыз.
2. Содан кейін макросты мынамен ауыстырыңыз:

Sub InsertBreakOnEachPage()
  Dim nTotalPageNumber As Integer
 
  For nTotalPageNumber = 1 To Selection.Information(wdNumberOfPagesInDocument)
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=nTotalPageNumber
    Application.Browser.Target = wdBrowsePage
    ActiveDocument.Bookmarks("\page").Range.Select
    Selection.Collapse wdCollapseEnd
    Selection.InsertBreak Type:=wdSectionBreakContinuous
  Next
End Sub

Бұл макрост қолданыстағы құжаттың әр парағының соңына бөлім үзілімін кірістіреді.

3-әдіс: Бірнеше құжаттардың әр парағына бөлімдер үзілімін енгізу

1. Бастау үшін, барлық мақсатты құжаттарды бір қалтаға салыңыз.
2. Содан кейін макросты тиісті нұсқаулармен орнатыңыз және іске қосыңыз.
3. Бұл жолы келесі кодтарды қолданыңыз:

Sub InsertBreaksIntoMultiDoc()
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nTotalPageNumber As Integer
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "No folder is selected! Please select the target folder."
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    For nTotalPageNumber = 1 To Selection.Information(wdNumberOfPagesInDocument)
      Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:=nTotalPageNumber
      Application.Browser.Target = wdBrowsePage
      ActiveDocument.Bookmarks("\page").Range.Select
      Selection.Collapse wdCollapseEnd
      Selection.InsertBreak Type:=wdSectionBreakContinuous
    Next
    objDoc.Save
    objDoc.Close
    strFile = Dir()
  Wend
End Sub

4. Макросты «Шолу» терезесі іске қосады. Құжаттар сақталатын қалтаны таңдап, «ОК» батырмасын басыңыз.

Процесс бірнеше секундтан аспауы керек.

Құжаттарды бұзуға арналған ыңғайлы құрал

Бұзылған құжаттармен кездестіру көңілсіз жағдай. Мұндай сценарийде көмектесе алатын жақсы және сенімді құрал Word бағдарламасын жөндеу құжаттар мазасыздықты едәуір жеңілдетуі керек. Сондықтан жөндеу құралын таңдау кезінде сізге өте абай болу керек. Жеткіліксіз бағдарлама одан әрі зақымдануы мүмкін.

Автордың кіріспесі:

Вера Чен - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. Excel-ді қалпына келтіру және pdf бағдарламалық жасақтама өнімдерін жөндеу. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com