Түрлі беттерде әртүрлі санаттары бар Outlook тапсырмаларының тізімдерін басып шығарудың 2 жолы

Outlook тапсырмаларына әртүрлі түс санаттарын тағайындаған болсаңыз және енді әртүрлі беттердегі әртүрлі санаттары бар тапсырмалар тізімін басып шығарғыңыз келсе, осы мақаланы қараңыз. Мұнда біз сізге оны алудың 2 әдісімен бөлісеміз.

Тапсырмаларыңызды жіктеу және жақсы басқару үшін тапсырмаларыңызға түс санаттарын қолданған боларсыз. Енді әртүрлі беттердегі әртүрлі санаттары бар тапсырмалар тізімдерін басып шығарғыңыз келсе, оқыңыз. Төменде біз сізге оны алудың 2 әдісін ұсынамыз.

1-әдіс: Тапсырмалар тізімдерін бір-бірлеп қолмен басып шығару

1. Алдымен, Outlook бағдарламасында «Тапсырмалар» тақтасына кіріңіз.
2. Содан кейін Тапсырма қалтасын ашыңыз.
3. Содан кейін «Іздеу» таспасын белсендіру үшін «Ctrl + E» пернелер тіркесімін басыңыз.
4. Осыдан кейін «Іздеу» қойындысында «Санаттастыру» түймесін басыңыз.
5. Ашылмалы тізімнен түс санатын таңдаңыз.
6. Содан кейін тізімде тек таңдалған санаты бар тапсырмалар ғана қалады.
7. Енді осы тапсырмалар тізімін басып шығару үшін «Файл» > «Басып шығару» тармағына өтіңіз.
8. Содан кейін, дәл осылай басқа түс санаттары бар тапсырмалар тізімдерін бір-бірлеп қолмен басып шығарыңыз.

2-әдіс: VBA арқылы тапсырмалар тізімдерін пакеттік басып шығару

1. Ең басында, VBA редакторын іске қосыңыз «Outlook бағдарламасында VBA кодын қалай іске қосуға болады«.
2. Содан кейін, «MS Excel нысан кітапханасына» сілтемені «VBA бағдарламасында объект кітапханасына сілтемені қалай қосуға болады«.
3. Келесі, келесі VBA кодын модульге көшіріңіз.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Содан кейін осы макросты бірден іске қосу үшін «F5» пернесін басыңыз.
5. Макрос аяқталған кезде, келесі скриншотта көрсетілгендей әртүрлі санаттары бар тапсырмалар тізімдері әртүрлі беттерде басып шығарылады.

Бұзылған PST файлынан құнды деректерді қайтарыңыз

Қолжетімсіз PST файлына ұшырасаңыз, келесі қадамыңыз сөзсіз PST жөндеу. Бұл жағдайда алдымен кіріс жәшігін жөндеу құралын қолдануға болады. Егер ол сәтсіз болса, басқа сыртқы құралды қолданып көруге болады, мысалы DataNumen Outlook Repair. Ол PST деректерін жылдам қалпына келтіруге қабілетті.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. mdf қалпына келтіру және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com