Сөздік құжаттан бөлімдер шығарудың 2 жылдам әдісі

Осы мақалада біз сізге Word құжатыңыздан бөлімдерді басқасына немесе бірнеше бөлімдерге бөлудің жылдам және қарапайым 2 әдісін ұсынамыз.

Мазмұнды бір құжаттан екінші құжатқа бөлу жиі кездеседі. Алдыңғы мақалада біз құжаттан парақтарды қалай шығаруға болатынын талқыладық. Толық ақпарат алу үшін сіз осы мақаланы таба аласыз: Word құжатыңыздан жеке беттерді шығарудың 2 жылдам әдісі

Бүгін біз сізге бөлімдер бойынша қалай шығаруға болатынын көрсетеміз.    

1-әдіс: Ағымдағы бөлімді жаңа құжатқа бөліп алу

1. Ең алдымен, курсорды мақсатты бөлімге орналастырыңыз.
2. Word бағдарламасында VBA редакторын шақыру үшін келесі «Alt + F11» пернелерін басыңыз.
3. Содан кейін сол жақ бағанда «Қалыпты» батырмасын басыңыз.
4. Мәзір жолағында «Кірістіру» батырмасын басыңыз.
5. Содан кейін ашылмалы мәзірден «Модуль» таңдаңыз.
6. Жаңа модульді ашу үшін екі рет басыңыз және келесі кодтарды қойыңыз:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. Содан кейін мәзір жолағында «Іске қосу» батырмасын басыңыз немесе «F5» пернесін басыңыз.
8. Содан кейін «Шолу» терезесі пайда болады. Жаңа құжатты сақтайтын орынды таңдап, «ОК» батырмасын басыңыз.
9. «Файл атауы» өрісіне жаңа файлдың атауын енгізіп, «ОК» батырмасын басыңыз.

Енді сіз бөлімді жаңа құжатқа шығардыңыз.

2-әдіс: Құжаттағы әр бөлімді жеке жаңадан шығару

Бұл сізге құжаттың барлық бөлімдерін өңдеуге көмектеседі. Әрине, бізге де макро қажет болады.

1. Бастау үшін, мақсатты құжатты ашыңыз.
2. Содан кейін макросты орнату және іске қосу үшін 1-тәсілдегі қадамдарды орындаңыз.
3. Тек осы жолы сол макросты мына макромен ауыстырыңыз:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. «Шолу» терезесінде сақтау жолын таңдап, «ОК» батырмасын басыңыз.

Тітіркендіргіш сөз қателерін түзету

Оны пайдалану кезінде кейбір Word қателіктері кездеседі. Тітіркендіргіш болуы мүмкін, біз оған уақыт бөлуіміз керек сөзді қалпына келтіру мүмкіндігінше тезірек. Ұзақ уақытқа созылғандықтан, деректердің жоғалуы соғұрлым күрделене түседі. Сондықтан жөндейтін қызметтік бағдарламаны алдын-ала алу ұсынылады.

Автордың кіріспесі:

Вера Чен - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. бүлінген xls және pdf бағдарламалық жасақтама өнімдерін жөндеу. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com