Wordテーブルの空白の行と列を削除する3つの高速な方法

この記事では、Wordの表から空白の行と列を削除する3つの簡単な方法を説明します。

テーブルは、特にさまざまなタイプのデータを保持する場合に、ドキュメントに不可欠です。 場合によっては、長いテーブルがXNUMXページを超え、複数に及ぶことがあります。 したがって、テーブルが長く複雑になると、それを単純化するために実行できる対策があります。 たとえば、不要な空白の行と列を削除できます。

使用できる3つの方法は次のとおりです。

方法1：空白の行と列を手動で削除する

1. まず、空白の行または列を選択します。
2. 次に、右クリックしてコンテキストメニューを表示します。 メニューで、それに応じて「行の削除」または「列の削除」を選択します。

残念ながら、この方法で複数の連続していない行または列を選択して、それらを一緒に削除することはできません。 この要求については、以前の記事を参照してください。 Wordテーブルの複数の行または列をバッチ削除する5つの簡単な方法

方法2：テーブル内のすべての空白の行と列をバッチ削除する

方法1には制限があります。 そのため、VBAコードを使用してテーブル内の行と列をバッチ削除する方法を提供します。

1. まず、カーソルを対象テーブル内に配置します。
2. 次に、「Alt + F11」を押してVBAエディターをトリガーします。
3. エディターで、最初に「通常」プロジェクトをクリックします。
4. 次に、メニューバーの[挿入]タブをクリックします。
5. ドロップダウンメニューで、「モジュール」を選択します。
6. モジュールをダブルクリックして開き、次のコードをそこに貼り付けます。

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. 最後に、メニューバーの「実行」ボタンをクリックするか、「F5」を押します。

数秒で、そのテーブルのすべての空白の行と列が削除されます。

方法3：ドキュメント内のすべてのテーブルのすべての空白の行と列をバッチ削除する

1. まず、方法2の手順を繰り返して、マクロをインストールして実行します。
2. 今回のみ、そのマクロを次のように置き換えます。

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

壊れたドキュメントを回復する

今では失われたデータを復元する方法は複数あります。たとえば、バックアップを利用することは常に最優先事項です。最新の情報を取り戻すというニーズがそれで満たされない場合は、 ドキュメントの修復 ツール。

著者紹介：

Vera Chenは、のデータ復旧の専門家です。 DataNumen、Inc。は、以下を含むデータ復旧技術の世界的リーダーです。 xlsx修復 (NAIST) と pdf ソフトウェア製品を修理します。 詳細については、次のWebサイトをご覧ください。 WWW。datanumen.com