Cara Cepat Mengekspor Statistik Voting dari Email Outlook ke Lembar Kerja Excel

Jika Anda telah mengirim email dengan tombol pemungutan suara, setelah penerima mengirimkan balasannya kepada Anda, Anda mungkin ingin menghitung dan mengekspor statistik pemungutan suara ke lembar kerja Excel. Jadi, di p iniost, kami akan mengajari Anda cara mencapainya dengan cepat.

Outlook sangat canggih bahkan menawarkan fitur "Voting". Artikel saya sebelumnya "Penggunaan Terampil MS Outlook untuk Voting”Telah mengajarkan bagaimana memanfaatkannya secara efektif. Juga, most waktu, setelah pemungutan suara, Anda dapat melanjutkan untuk mengekspor statistik pemungutan suara ke lembar kerja Excel karena beberapa alasan, seperti ingin mencetak statistik. Tapi Outlook tidak mendukung ini secara default. Jadi, berikut ini, kami akan mengajari Anda cara mewujudkannya seperti gabus.

Ekspor Statistik Pemungutan Suara dalam Email ke Lembar Kerja Excel

1. Pertama-tama, luncurkan aplikasi Outlook Anda.
2. Kemudian Anda harus menekan tombol "Alt + F11" di jendela utama Outlook.
3. Selanjutnya di jendela "Microsoft Visual Basic for Applications", Anda harus mengaktifkan "Microsoft Excel Object Library ”. Klik "Alat"> "Referensi". Kemudian di kotak dialog popup, tandai kotak centang di depan "Microsoft Excel Object Library ”dan tekan“ OK ”terakhir.
4. Setelah itu, Anda dapat memasukkan modul baru atau membuka modul yang tidak digunakan.
5. Selanjutnya, salin dan tempel kode VBA berikut ke dalam modul ini.

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

5. Setelah itu, untuk memudahkan akses, sebaiknya Anda menambahkan makro baru ke Bilah Alat Akses Cepat.
6. Akhirnya, Anda bisa mencobanya.

• Pertama, pilih email sumber yang berisi tombol voting.
• Lalu klik tombol makro di Bilah Alat Akses Cepat.
• Setelah makro ini selesai berjalan, Anda bisa menelusuri ke folder lokal yang sudah ditentukan sebelumnya, di mana Anda akan melihat buku kerja Excel baru.
• Buka buku kerja Excel ini. Sekarang Anda akan melihat statistik pemungutan suara, seperti gambar di bawah ini:

Tidak Ada Yang Dapat Mencegah Kesalahan Outlook Secara Menyeluruh

Meskipun Outlook diberkahi dengan berbagai kemampuan, tidak ada fitur seperti itu untuk membantu kami menghindari kesalahan Outlook. Semua jenis faktor dapat menyebabkan kesalahan Outlook. Misalnya, jika Anda sering keluar dari Outlook dengan tidak semestinya, Anda kemungkinan besar akan menderita Korupsi PST. Dalam skenario seperti itu, Anda tidak punya pilihan selain menggunakan beberapa alat ampuh untuk menyelamatkan file PST Anda, seperti DataNumen Outlook Repair. Ini telah mendapatkan banyak pujian karena tingkat pemulihannya yang tinggi.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk mdf korup dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com