Cara Batch Ekspor Beberapa Email Outlook menjadi Satu Dokumen Word melalui VBA

Solusi Outlook September 29, 2025
Bagikan sekarang:

Jika Anda ingin mengekspor banyak email Outlook menjadi satu dokumen kata, Anda dapat menggunakan kode VBA yang diperlihatkan di artikel ini. Ini dapat membantu Anda menyelesaikan tugas ini dalam hitungan detik.

Saya pernah memperkenalkan cara mengonversi email Outlook menjadi dokumen Word di artikel saya sebelumnya - “2 Metode Efektif untuk Mengonversi Email Outlook menjadi dokumen Word". Namun, kedua cara yang disebutkan dalam hal ituost akan menjadi tidak berdaya jika Anda ingin mengekspor banyak email ke dalam satu dokumen Word. Karenanya, di sini kami akan mengajari Anda cara lain. Sekarang, baca terus untuk mendapatkannya secara terperinci.

Ekspor Batch Beberapa Email Outlook ke dalam Satu Dokumen Word melalui VBA

Ekspor Batch Beberapa Email Outlook ke dalam Satu Dokumen Word

  1. Untuk start dengan, luncurkan program Outlook Anda.
  2. Kemudian, setelah memasuki jendela utama Outlook, Anda perlu menekan tombol "Alt + F11".
  3. Selanjutnya Anda akan mendapatkan akses ke editor Outlook VBA, di mana Anda harus membuka modul kosong.
  4. Selanjutnya, salin kode VBA di bawah ini ke jendela modul yang terbuka.
Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

Kode VBA - Ekspor Batch Beberapa Email Outlook ke dalam Satu Dokumen Word

  1. Setelah itu, Anda lebih baik menambahkan proyek VBA baru ini ke Bilah Alat Akses Cepat atau pita.
  2. Akhirnya, Anda bisa mencobanya.
  • Pertama-tama, pilih beberapa email Outlook.
  • Kemudian cari dan klik tombol makro yang baru ditambahkan.
  • Setelah Anda diminta "Selesai", Anda dapat menelusuri ke folder lokal yang telah ditentukan untuk menemukan dokumen Word baru.
  • Buka dokumen ini, di mana Anda dapat melihat semua email yang dipilih telah diekspor.

Simpan Alat Pemulihan Perkasa di Dekat Anda

Terlepas dari banyaknya fungsi, Outlook tetap tidak kebal dari kesalahan. Jika Anda terbiasa membiarkan kesalahan, dengan mereka menumpuk, Outlook crash pasti akan terjadi. Pada titik itu, penting untuk menggunakan alat pemulihan yang kuat dan efektif, seperti DataNumen Outlook Repair. Ia berpengalaman dalam Perbaikan PST. Selama dengan itu, Anda tidak perlu khawatir tentang kehilangan data prospek lagi.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk mdf rusak dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com

Bagikan sekarang:

Komentar ditutup.